СИСТЕМНАЯ МАКРОБИБЛИОТЕКА
РУКОВОДСТВО ПРОГРАММИСТА

589.7545471.00042-01 33 01

1. Назначение и условия применения

Ядром операционной системы ФОДОС-2 (главной управляющей программой) является монитор. В зависимости от конфигурации технических средств и потребностей пользователя может использоваться один из трёх мониторов ФОДОС-2: монитор одного задания (SJ), монитор основного-фонового задания (FB) и монитор расширенной памяти (XM). Всё изложенное в данном документе, если не оговорено особо, относится к любому монитору ФОДОС-2.

Монитор выполняется параллельно с прикладными программами (программами пользователя) и обеспечивает выполнение следующих функций:

• инициализация и управление характеристиками (параметрами) операционной системы;
• распределение системных ресурсов и получение информации о состоянии операционной системы;
• интерпретация команд;
• операции с файлами;
• управление вводом-выводом;
• обеспечение связи между заданиями;
• завершение или временный приостанов программы;
• работа с расширенной памятью.

Связь пользователя с ФОДОС-2 осуществляется главным образом с помощью команд клавиатурного монитора и .MCALL запросов.

Программные запросы обеспечивают разнообразные возможности для манипулирования файлами, выполнения операций ввода-вывода, управления выполнением и приостановкой программ и реализации других стандартных системных функций.

Программный запрос представляет собой макрокоманду, помещаемую пользователем в исходный текст программы на языке Ассемблера (программа может содержать несколько .MCALL запросов).

Каждая макрокоманда заменяется последовательностью обычных символических команд. Этот процесс называется макрорасширением и выполняется во время ассемблирования.

Для формирования макрорасширения Ассемблер использует макроопределения, включённые в системную макробиблиотеку SYSMAC.SML, которая находится на системном томе и может быть использована любой программой.

Большинство .MCALL запросов используют машинную команду EMT, которая обеспечивает передачу управления монитору из программы, как только при выполнении этой программы очередь доходит до команды EMT.

Младший байт команды EMT содержит код в интервале от 340 до 377₍₈₎, определяющий местоположение передаваемых монитору аргументов (см. табл. 1).

2. Обращение к системной макробиблиотеке

Для выполнения операций средствами операционной системы программы пользователя обращаются к монитору через программные запросы. В данном разделе описан формат и назначение .MCALL запросов операционной системы.

Имена всех .MCALL запросов начинаются символом "точка" (.), что отличает их от макрокоманд, определяемых пользователем.

Все программные запросы, используемые в программе, должны быть определены в директиве .MCALL.

В ФОДОС-2 используются два формата .MCALL запросов:

1. .PRGREQ ARG1,ARG2,...,ARGN
2. .PRGREQ AREA,ARG1,...,ARGN

В этих форматах .PRGREQ представляет собой имя программного запроса, AREA - указатель на адрес блока аргументов, ARG1,ARG2,...,ARGN - аргументы программного запроса.

Программные запросы первого формата вызывают генерацию команды EMT с кодом 374 или одной из команд EMT 340-357.

Программные запросы, использующие команду EMT 374, помещают в младший байт регистра R0 номер канала, а в старший - функциональный код (см. рис. 1).

Рис.1

Одним из .MCALL запросов, использующих EMT 374, является запрос .DATE. Макроопределение для этого запроса следующее:

.MACRO .DATE
      MOV     #10.*^O400,%0
      EMT     ^374
.ENDM

Соответствующий запросу .DATE функциональный код, равный 10., помещается в старший байт регистра R0, а номер канала (0) - в младший байт регистра R0.

Программные запросы, использующие EMT 340-357, помещают аргументы (если они заданы) в стек и/или в R0.

Программный запрос .CSIGEN является примером программного запроса, использующего EMT 344. Ниже представлено упрощённое макроопределение для этого запроса:

.MACRO .CSIGEN DEVSPC,DEFEXT,CSTRNG,LINBUF
.IFF NB <LINBUF>
      MOV     LINBUF,-(6.)
      MOV     DEVSPC,-(6.)
.IFF NB <LINBUF>
      INC     (6.)
      MOV     DEFEXT,-(6.)
.IF B CSTRNG
      CLR     -(6.)
.IFF
.IF IDN CSTRNG,#0
      CLR     -(6.)
.IFF
      MOV     CSTRNG,-(6.)
.ENDC
.ENDC
      EMT     ^O344
.ENDM

Все указанные аргументы помещаются в стек пользователя (см. рис. 2) и используются монитором при выполнении запроса .CSIGEN.

Рис.2

Программные запросы второго формата вызывают генерацию команды EMT с кодом 375.

Формат блока аргументов для EMT 375 представлен на рис. 3.

Рис.3

Некоторые аргументы .MCALL запросов могут быть опущены. Если отсутствует аргумент AREA, то предполагается что он содержится в R0. Если не указаны (опущены) какие-либо из аргументов от ARG1 до ARGN, то содержимое соответствующих этим аргументам слов в блоке аргументов не изменяется.

Например, при выполнении запроса

              .PRGREQ AREA,ARG1,ARG2

регистр R0 содержит адрес блока аргументов, второе слово содержит ARG1, третье - ARG2.

При выполнении запроса

              .PRGREQ AREA

старший байт первого слова блока аргументов содержит функциональный код. Содержимое других слов блока аргументов не изменяется.

Если в запросе

              .PRGREQ ,ARG1

опущен аргумент AREA, то предполагается, что он содержится в R0 (функциональный код в этом случае в блок аргументов не заносится).

Блок аргументов может формироваться Макроассемблером во время трансляции программы или непосредственно пользователем, например:

      1) MOV  #ARG1,AREA+2
         MOV  #ARG2,AREA+4
         .PRGREQ      #AREA

      2) MOV  #AREA,R0
         .PRGREQ      ,#ARG1,#ARG2

      3) MOV  #AREA,R0
         MOV  #ARG1,2(R0)
         MOV  #ARG2,4(R0)
         MOV  #CODE*400!CHAN,(R0)
         .PRGREQ

Во всех вышеприведённых примерах определяется один и тот же программный запрос.

В примере, который следует ниже, приведён один из возможных способов формирования блока аргументов для программного запроса .TWAIT.

         .MCALL  .PRINT,.TWAIT
START:   .TWAIT  #EMTBLK
         .PRINT  #MSG
         BR      START

EMTBLK:  .BYTE   0,24
         .WORD   TIME

TIME:    .WORD   0,10.*50
         .ASCIZ  /ЧЕРЕЗ 10 СЕКУНД - ПЕЧАТЬ  СООБЩЕНИЯ/
         .END    START

2.1. Адресация аргументов

Все аргументы .MCALL запросов служат в качестве операнда источника команды MOV и блок аргументов должен содержать непосредственно значения аргументов.

Поэтому необходимо помнить, что аргументы .MCALL запросов должны быть допустимыми в языке Ассемблера и точно представлять требуемую величину. Если величина является константой или символическим именем пользователя, то должен быть использован непосредственный метод адресации (#), например:

    .PRGREQ #AREA,#4

Если величина является содержимым регистра, то должна быть использована мнемоника регистра (RN). Если величина является содержимым ячейки памяти, то должна быть использована метка этой ячейки, например:

        .PRGREQ LIST,NUMBER
                 .
                 .
                 .
LIST:   .WORD   AREA
NUMBER: .WORD   4

Примечание. При выполнении запроса, содержимое регистров общего назначения, кроме R0, не изменяется. Указатель стека не переустанавливается. Исключением является вызов интерпретатора командной строки (запросы .CSIGEN, .CSISPC).

2.2. Ключевой аргумент CODE

Ключевой аргумент CODE позволяет использовать один и тот же блок аргументов для различных .MCALL запросов, имеющих одни и те же аргументы, но различные функциональные коды. Использование этого ключевого аргумента уменьшает размер программы и время её выполнения. Аргумент CODE может иметь два значения: CODE=SET (занести функциональный код) и CODE=NOSET (не заносить функциональный код).

Пример.

         .WRITW  #AREA,#CHAN,#BUFF,#WCNT,#BLK
            .
            .
            .
         .READW  #AREA,CODE=SET
            .
            .
            .

3. Входные и выходные данные

Аргументы .MCALL запросов являются входными данными для монитора ФОДОС-2. В табл. 2 приведены их условные обозначения. В этом разделе также приведены некоторые основные понятия, которые используются при обращении к макробиблиотеке.

3.1. Номер канала

Номер канала (CHAN) представляет собой логический идентификатор файла и используется монитором при выполнении запрашиваемых операций. Номер канала может иметь значение от 0 до 254₍₁₀₎ (0-376₍₈₎). Канал с номером 255₍₁₀₎ резервируется для системных операций.

Каждый открытый файл монитор логически связывает с определённым каналом (элементом структуры монитора, точно определяющим файл в операционной системе). Для обращения к файлу достаточно указать номер соответствующего канала.

3.2. Блок устройства

Блок устройства (DBLK) представляет собой блок информации в кодах RADIX-50, который содержит физическое или логическое имя устройства, имя и тип файла. Размер блока - 4 слова.

Пример:

.RAD50 /DX1/
.RAD50 /FIL/
.RAD50 /NAM/
.RAD50 /TYP/

Имя устройства, имя и тип файла должны быть левоопределёнными в каждом поле операнда (т.е. непосредственно следовать за ограничителем операнда директивы .RAD50).

Допускается запись блока устройства в следующем виде:

.RAD50 /DX1FILNAMTYP/

При этом каждое пропущенное поле операнда должно заменяться пробелом.

3.3. Блок аргументов EMT

Общий вид блока аргументов команды EMT показан на рис. 4. Чётный байт 1-го слова содержит номер канала, определённый в макрокоманде. Если номер канала не требуется, то чётный байт содержит 0. Нечётный байт 1-го слова блока содержит функциональный код макрокоманды (каждому программному запросу соответствует свой функциональный код). Остальные слова блока содержат аргументы (если они заданы), определённые в макрокоманде.

Рис.4

3.4. Подпрограммы завершения

Подпрограмма завершения создаётся пользователем и выполняется при наступлении события. Событие может заключаться в завершении операции ввода-вывода, может быть вызвано прерыванием от внешнего устройства, истечением заданного интервала времени и т.д.

На входе в подпрограмму завершения регистр R0 содержит слово состояния канала, а R1 - восьмеричный номер канала для операции.

В режиме SJ подпрограммы завершения являются асинхронными и могут прерывать друг друга. В режимах FB и XM, подпрограммы завершения не прерывают друг друга, а организуются в очередь.

3.5. Требование USR

Для выполнения некоторых .MCALL запросов необходимо, чтобы компонента монитора USR находилась в оперативной памяти. Требование USR программным запросам описано в табл. 3. Заметим, что запрос .CLOSE на устройствах нефайловой структуры (LP:, TT:, PC:, и т.д.) не требует наличия USR в памяти.

Программа USR не является реентерабельной; если USR используется одним заданием (в режиме FB), другое задание, требующее USR, будет ждать её освобождения.

Запросы, помеченные в табл. 3 звёздочкой, всегда требуют загрузки новой копии USR перед их выполнением (даже, если USR в этот момент находится в памяти).

1)  Если канал был открыт по .ENTER ;

2)  Если USR находится в состоянии свопинга;

3)  Если USR не используется другим заданием.

4. Сообщения

При обработке запросов, монитор может обнаружить условия ошибок. Программные запросы информируют об этом пользователя, используя C-разряд, байт ошибок (52-ой байт в области связей системы) и печать на терминале сообщений монитора. C-разряд очищается после выполнения запроса и устанавливается в случае ошибки. Для обнаружения ошибки за запросом должна следовать команда BCS или BCC. Когда установлен C-разряд, байт ошибок содержит код ошибки.

При возникновении серьёзных ошибок (в этом случае монитор печатает соответствующее сообщение на терминале) управление передаётся монитору. Для анализа подобных ошибок рекомендуется использовать программный запрос .SERR. В приложении 1 перечислены коды ошибок .MCALL запросов и причины, вызывающие эти ошибки.

Информация о сообщениях дана в [3].

5. Программные запросы

Существуют следующие типы .MCALL запросов:

• Запросы для операций с файлами;
• Запросы для организации ввода-вывода данных;
• Запросы общего назначения;
• Запросы расширенной памяти;
• Запросы для драйверов.

В таблице 4 перечислены программные запросы, которые могут использоваться в любом из режимов (SJ, FB, XM). Запросы, помеченные в табл. 4 символами "МТ", можно использовать только при наличии в системе мультитерминальной поддержки.

В табл. 5 перечислены программные запросы, которые используются основным/фоновым заданием при наличии расширенной памяти. Программные запросы, помеченные символами "XM" можно использовать только в режиме XM.

Описание .MCALL запросов для программ - драйверов устройств даётся в [1].

Описание запросов расширенной памяти даётся в [2].

5.1. Программные запросы для операций с файлами

5.1.1. .CHCOPY (режим FB, XM)

Запрос .CHCOPY открывает канал для ввода данных и логически связывает его с каналом другого задания открытым для ввода или вывода. Запрос может использоваться основной, фоновой программами, а также системным заданием. Запрос .CHCOPY допустим только для файлов, которые находятся на дисках; однако система не обнаружит ошибки, если используется другое устройство. Для того чтобы закрыть канал, открытый по .CHCOPY необходимо использовать запросы .CLOSE или .PURGE.

Формат макрокоманды:

.CHCOPY AREA,CHAN,OCHAN[,JOBBLK]

Формат блока аргументов EMT:

          AREA:   .BYTE   CHAN,13
                  .WORD   OCHAN
                  .WORD   JOBBLK

Пример.

  ;ПРИМЕР СОСТОИТ ИЗ ДВУХ ПРОГРАММ. ПЕРВАЯ ИЗ ПРОГРАММ
  ;(ОСНОВНАЯ) ВЫПОЛНЯЕТ ПЕРЕДАЧУ ДАННЫХ ВО ВТОРУЮ -
  ;ФОНОВУЮ ПРОГРАММУ.
          .TITLE  CHCOPF.MAC
  ;ОСНОВНАЯ ПРОГРАММА
          .MCALL  .ENTER,.PRINT,.SDATW,.RCVDW,.CLOSE,.WRITW
          .MCALL  .EXIT
  STARTF: MOV     #AREA,R5
          .ENTER  R5,#0,#FILE,#5          ;СОЗДАТЬ ФАЙЛ
          .WRITW  R5,#0,#RECRD,#256.,#4   ;ЗАПИСАТЬ БЛОК
          BCS     ENTERR
          .SDATW  R5,#BUFR,#2             ;ПЕРЕДАТЬ СООБЩЕНИЕ
          ;       .
          .RCVDW  R5,#BUFR,#1
          .CLOSE  #0
          .PRINT  #FEXIT
          .EXIT
  ENTERR: .PRINT  #ERMSG
          .EXIT
  FILE:   .RAD50  /DK QUFILE/
          .RAD50  /TMP/
  AREA:   .BLKW   5
  BUFR:   .WORD   0                       ;НОМЕР КАНАЛА
          .WORD   4                       ;НОМЕР БЛОКА
  RECRD:  .BLKW   256.
  ERMSG:  .ASCIZ  /ОШИБКА .ENTER/
  FEXIT:  .ASCIZ  /КОНЕЦ ОСНОВНОЙ ПРОГРАММЫ/
          .END    STARTF

          .TITLE  CHCOPB.MAC
  ;ФОНОВАЯ ПРОГРАММА
          .MCALL  .CHCOPY,.RCVDW,.READW,.EXIT,.PRINT,.SDATW
  STARTB: MOV     #AREA,R5
          .RCVDW  R5,#MSG,#2      ;ПОЛУЧИТЬ СООБЩЕНИЕ
          BCS     1¤
          .CHCOPY R5,#0,MSG+2     ;НОМЕР КАНАЛА ИЗ MSG+2
          BCS     2¤
          .READW  R5,#0,#BUFF,#256.,MSG+4 ;ЧИТАТЬ БЛОК
          BCS     3¤
          ;       .
          .SDATW  R5,#MSG,#1
          .PRINT  #BEXIT
          .EXIT
  1¤:     MOV     #NOJOB,R0
          BR      4¤
  2¤:     MOV     #NOCH,R0
          BR      4¤
  3¤:     MOV     #RDERR,R0
  4¤:     .PRINT
          .EXIT
  AREA:   .BLKW   5
  MSG:    .BLKW   3               ;БУФЕР ДЛЯ СООБЩЕНИЯ
  BUFF:   .BLKW   256.
  BEXIT:  .ASCIZ  /КОНЕЦ ФОНОВОЙ ПРОГРАММЫ/
  NOJOB:  .ASCIZ  /НЕТ ОСНОВНОГО ЗАДАНИЯ/
  NOCH:   .ASCIZ  /НЕ ОТКРЫТ КАНАЛ ДЛЯ ОСНОВНОГО ЗАДАНИЯ/
  RDERR:  .ASCIZ  /ОШИБКА ЧТЕНИЯ/
          .END    STARTB

5.1.2. .CLOSE

Запрос .CLOSE завершает действие на указанном канале и освобождает его для использования в другой операции. Для выполнения запроса драйвер соответствующего устройства должен находиться в памяти.

Формат макрокоманды

        .CLOSE CHAN

Формат блока аргументов EMT:

          AREA:   .BYTE   CHAN,6

Для того чтобы сделать файл постоянным на томе необходимо на соответствующем канале, открытом для вывода, выполнить запрос .CLOSE. Запрос .CLOSE на неоткрытом канале игнорируется.

.CLOSE, выполняемый на канале, который был открыт по .ENTER вызывает корректировку справочника устройства для определения файла как постоянного на этом устройстве. Если файл открыт по .LOOKUP, то корректировки справочника не происходит.

Если устройство, связанное с указанным каналом, уже содержит файл с тем же именем и типом, что и вновь созданный файл, то старая копия файла стирается, когда новый файл становится постоянным.

Если на устройстве уже существует защищённый файл с тем же именем, то текущий файл закрывается, но появляются два файла с одинаковыми именами.

Примечание. Монитор информирует программу пользователя об ошибке при выполнении запроса .CLOSE только в том случае, если до этого был выполнен запрос .SERR.

Пример использования .CLOSE см. в описании запроса .CSISPC.

5.1.3. .DELETE

Запрос .DELETE удаляет файл из справочника указанного устройства. .DELETE недопустим для магнитных лент.

Формат макрокоманды:

.DELETE AREA,CHAN,DBLK

Примечания:

1. Обращение к открытому каналу приводит к ошибке;
2. Удалённый файл в листинге справочника устройства будет описан как неиспользуемая область (UNUSED) того же размера;
3. Запрос .DELETE на устройствах нефайловой структуры игнорируется;
4. При выполнении .DELETE необходимо, чтобы драйвер соответствующего устройства находился в памяти;
5. После выполнения .DELETE, указанный канал освобождается для дальнейшего использования.

Пример использования .DELETE см. в описании запроса .CSISPC.

5.1.4. .ENTER

Запрос .ENTER резервирует область на определённом устройстве и заносит в справочник устройства запись о создании временного файла. По запросу .ENTER монитор идентифицирует номер канала, определённый в запросе, с указанным файлом. Заметим, что если программа имеет оверлейную структуру, то 15-й канал используется оверлейным драйвером и не должен модифицироваться программой пользователя.

Формат макрокоманды:

.ENTER AREA,CHAN,DBLK,LEN[,SEQN]

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,2
               .WORD   DBLK
               .WORD   LEN
               .WORD   SEQN

Файл, созданный по .ENTER не является постоянным до тех пор, пока на соответствующем канале не будет выполнен запрос .CLOSE. Запросы .LOOKUP и .SAVESTATUS недействительны для файлов, которые не являются постоянными. Однако чтение такого файла возможно посредством обращения к номеру соответствующего блока. Если на соответствующем канале выполняется .CLOSE, то любой существующий на томе постоянный, незащищённый файл с тем же именем и типом стирается и новый файл становится постоянным. Хотя область для файла резервируется при выполнении .ENTER, фактическая длина файла определяется после выполнения .CLOSE.

Каждое задание может иметь до 255 одновременно открытых файлов. Если требуется, все 255 файлов могут быть открыты для вывода посредством .ENTER. Для выполнения .ENTER необходимо, чтобы драйвер соответствующего устройства был в памяти. После выполнения .ENTER регистр R0 будет содержать размер области тома, отведённый для создания нового файла.

Пример.

          .TITLE  ENTER.MAC
  ;В СЛЕДУЮЩЕМ ПРИМЕРЕ С ИСПОЛЬЗОВАНИЕМ ЗАПРОСА .ENTER
  ;ВЫПОЛНЯЕТСЯ КОПИРОВАНИЕ ФАЙЛА ENTER.SAV НА УСТРОЙСТВО
  ;DK:.

          .MCALL  .LOOKUP,.ENTER,.WRITW,.READW,.CLOSE
          .MCALL  .PRINT,.EXIT
          ERRBYT = 52
  START:  .LOOKUP #AREA,#0,#ENTER         ;СВЯЗАТЬ 0-ОЙ КАНАЛ
                                          ;С ФАЙЛОМ ENTER.SAV
          BCS     5¤
          MOV     R0,R3                   ;РАЗМЕР ФАЙЛА В R3
          .ENTER  #AREA,#1,#NEWFIL,R3     ;ОТКРЫТЬ НОВЫЙ ФАЙЛ
          BCS     6¤
          CLR     BLK
  1¤:     .READW  #AREA,#0,#BUFFR,#256.,BLK ;ЧИТАТЬ БЛОК
          BCC     2¤
          TSTB    @#ERRBYT                ;КОНЕЦ ФАЙЛА?
          BEQ     3¤                      ;ДА
          MOV     #RERR,R0
          BR      7¤
  2¤:     .WRITW  #AREA,#1,#BUFFR,#256.,BLK ;ЗАПИСАТЬ БЛОК
          INC     BLK
          BCC     1¤
          MOV     #WERR,R0
          BR      7¤
  3¤:     .CLOSE  #1
          MOV     #DONE,R0
          BR      7¤
  5¤:     MOV     #NOFIL,R0
          BR      7¤
  6¤:     MOV     #NOENT,R0
  7¤:     .PRINT
          .EXIT

  AREA:   .WORD   0
  BLK:    .WORD   0,0,0,0
  BUFFR:  .BLKW   256.
  ENTER:  .RAD50  /DK/
          .RAD50  /ENT/
          .RAD50  /ER/
          .RAD50  /SAV/
  NEWFIL: .RAD50  /DK/
          .RAD50  /NEWENT/
          .RAD50  /SAV/

  NOFIL:  .ASCIZ  /ФАЙЛ НЕ НАЙДЕН/
  NOENT:  .ASCIZ  /ОШИБКА .ENTER /
  WERR:   .ASCIZ  /ОШИБКА .WRITW /
  RERR:   .ASCIZ  /ОШИБКА .READW /
  DONE:   .ASCIZ  /КОПИРОВАНИЕ ЗАВЕРШЕНО/
          .EVEN
          .END    START

5.1.5. .LOOKUP

Используются две формы запроса .LOOKUP. Первая форма .LOOKUP связывает указанный канал с устройством и/или существующим файлом для выполнения операций ввода-вывода. Используемый канал будет "занят" до тех пор, пока не будет выполнен один из следующих запросов: .CLOSE, .SAVESTATUS, .SRESET, .HRESET, .PURGE, .CSIGEN (если номер канала в диапазоне от 0 до 10₍₈₎.

Заметим, что если программа имеет оверлейную структуру, то 15-ый канал используется оверлейным драйвером и не должен изменяться программой пользователя.

Если первое слово имени файла в блоке устройства (DBLK) содержит нуль и устройство есть устройство файловой структуры, то абсолютный блок 0 этого устройства определяется как "начало файла" (в этом случае говорят о нефайловом .LOOKUP). Этот метод допускает ввод-вывод для любого физического блока на устройстве. Если имя файла определено для устройства нефайловой структуры, то имя файла игнорируется.

Для выполнения .LOOKUP драйвер соответствующего устройства должен быть в памяти. После выполнения .LOOKUP, регистр R0 будет содержать длину открытого файла в блоках. После выполнения .LOOKUP для устройств несправочной структуры, регистр R0 будет содержать ноль.

Формат макрокоманды:

.LOOKUP AREA,CHAN,DBLK[,SEQN]

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,1
               .WORD   DBLK
               .WORD   SEQN

Пример 1.

          .TITLE  LOOKUP.MAC
  ;В ДАННОМ ПРИМЕРЕ, ИСПОЛЬЗУЮЩЕМ ЗАПРОС .LOOKUP,
  ;ОПРЕДЕЛЯЕТСЯ НАЛИЧИЕ НА УСТРОЙСТВЕ DK: РАБОЧЕГО
  ;ФАЙЛА, СОДЕРЖАЩЕГО ОЧЕРЕДЬ ФАЙЛОВ ДЛЯ ВЫВОДА НА
  ;УКАЗАННОЕ УСТРОЙСТВО.
  ;ЕСЛИ РАБОЧИЙ ФАЙЛ СУЩЕСТВУЕТ, ТО ЕГО РАЗМЕР
  ;(В БЛОКАХ) ПЕЧАТАЕТСЯ НА СИСТЕМНОМ ТЕРМИНАЛЕ.
          .MCALL  .LOOKUP,.PRINT,.EXIT
  START:  .LOOKUP #AREA,#0,#QUSPEC ;ОТКРЫТЬ ФАЙЛ
          BCC     1¤
          .PRINT  #NOFILE         ;ФАЙЛА НЕТ
          .EXIT
  1¤:     MOV     #SIZE,R1
          CALL    CNV10
          .PRINT  #BUFF
          .EXIT

  CNV10:  MOV     R0,-(SP)        ;ПОДПРОГРАММА
          CLR     R0              ;ПРЕОБРАЗОВАНИЯ РАЗМЕРА
  1¤:     INC     R0              ;ФАЙЛА ДЛЯ ВЫВОДА НА
          SUB     #10.,@SP        ;ТЕРМИНАЛ
          BGE     1¤
          ADD     #72,@SP
          DEC     R0
          BEQ     2¤
          CALL    CNV10
  2¤:     MOVB    (SP)+,(R1)+
          RETURN

  AREA:   .BLKW   3
  QUSPEC: .RAD50  /DK QUFILE/
          .RAD50  /TMP/
  BUFF:   .ASCII  /РАЗМЕР ФАЙЛА QUFILE.TMP = /
  SIZE:   .ASCIZ  /      /
  NOFILE: .ASCIZ  /НА DK: НЕТ ФАЙЛА QUFILE.TMP/
          .EVEN

          .END    START

Вторая форма .LOOKUP связывает канал с указанным заданием для обмена информацией в режимах FB и XM.

Формат макрокоманды:

.LOOKUP AREA,CHAN,JOBDES

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,1
               .WORD   JOBDES

Пример 2.

          .TITLE  SJLOOK.MAC
  ;В ДАННОМ ПРИМЕРЕ ЗАПРОС .LOOKUP ОТКРЫВАЕТ КАНАЛ
  ;ДЛЯ СИСТЕМНОГО ЗАДАНИЯ QUEUE.REL.
  ;ПРИМЕР ВЫПОЛНЯЕТСЯ ПОД УПРАВЛЕНИЕМ МОНИТОРОВ FB
  ;ИЛИ XM.
  ;

          .MCALL  .LOOKUP,.PRINT,.EXIT,.WRITW,.READW
  START:  .LOOKUP #AREA,#0,#QMSG  ;ОТКРЫТЬ КАНАЛ ДЛЯ QUEUE
          BCC     1¤
          .PRINT  #NOJOB
          .EXIT
  1¤:     .WRITW  #AREA,#0,#RMSJ,#6
          BCS     2¤
          .READW  #AREA,#0,#RMSJ,#6
          BCS     2¤
          .PRINT  #QRUN
          .EXIT
  2¤:     .PRINT  #MSGERR
          .EXIT
  AREA:   .BLKW   5
  QMSG:   .RAD50  /MQ/
          .ASCIZ  /QUEUE/
          .WORD   0,0
  RMSJ:   .WORD   0
          .ASCII  /SJLOOK/
  MSGERR: .ASCIZ  /ОШИБКА/
  NOJOB:  .ASCIZ  /QUEUE НЕ ЗАГРУЖЕНА/
  QRUN:   .ASCIZ  /QUEUE РАБОТАЕТ!/
          .EVEN
          .END    START

5.1.6. .PURGE

Запрос .PURGE освобождает указанный канал для использования в другой операции без выполнения каких-либо функций запросов .HRESET, .SRESET, .SAVESTATUS или .CLOSE. Временный файл, открытый на этом канале по .ENTER, аннулируется. Запрос .PURGE на свободном канале игнорируется.

Формат макрокоманды:

     .PURGE CHAN

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,3

Пример использования .PURGE см. в описании запроса .HERR.

5.1.7. .RENAME

Запрос .RENAME изменяет имя файла (недопустим в операциях с магнитной лентой).

Формат макрокоманды:

.RENAME AREA,CHAN,DBLK

Формат блока аргументов EMT:

          AREA:   .BYTE   CHAN,4
                  .WORD   DBLK

Например,

          .RENAME  #AREA,#7,#DXLK
          BCS  RNMERR
           .
           .
           .
   DBLK:  .RAD50 /DX1OLDFILMAC/
          .RAD50 /DX1NEWFILMAC/

Если файл с тем же именем, что и новое, уже существует на томе, то он удаляется. Повторное определение имени устройства DX1 в новой спецификации файла необходимо для правильного выполнения операции и не должно опускаться. После выполнения .RENAME используемый канал освобождается. Запрос .RENAME требует, чтобы драйвер соответствующего устройства был в памяти перед выполнением операции. Запрос .RENAME не выполняется для защищённых файлов.

Пример.

          .TITLE  RENAME.MAC
  ;В ДАННОМ ПРИМЕРЕ ЗАПРОС .RENAME ИСПОЛЬЗУЕТСЯ
  ;ДЛЯ ИЗМЕНЕНИЯ ИМЕНИ ФАЙЛА.
          .MCALL  .CSISPC,.RENAME,.FETCH,.PRINT,.SRESET,.EXIT
          ERRBYT = 52
  START:  .CSISPC #FILESP,#DEFEXT ;ВВОД КОМАНДНОЙ СТРОКИ
          .FETCH  #DRVLOD,#FILESP ;ЗАГРУЗИТЬ ДРАЙВЕР
          BCS     2¤
          MOV     #FILESP,R2
          MOV     #FILESP+46,R3
          MOV     @R2,#FILESP+36
          .REPT   4
          MOV     (R2)+,(R3)+
          .ENDR
          .RENAME #AREA,#0,#FILESP+36 ;ПЕРЕИМЕНОВАТЬ ФАЙЛ
          BCC     1¤
          DECB    @#ERRBYT        ;АНАЛИЗ ОШИБКИ
          BEQ     3¤
          MOV     #ILLOP,R0
          BR      4¤
  1¤:     .SRESET
          .EXIT

  2¤:     MOV     #FERR,R0
          BR      4¤
  3¤:     MOV     #NOFIL,R0
  4¤:     .PRINT
          BR      1¤

  AREA:   .BLKW   5
  DEFEXT: .WORD   0,0,0,0
  NOFIL:  .ASCIZ  /ФАЙЛ НЕ НАЙДЕН/
  ILLOP:  .ASCIZ  /НЕДОПУСТИМАЯ ОПЕРАЦИЯ/
  FERR:   .ASCIZ  /ОШИБКА .FETCH/
          .EVEN
  FILESP: .BLKW   39.*2
  DRVLOD  =.
          .END    START

5.1.8. .REOPEN

Запрос .REOPEN повторно связывает указанный канал с файлом, для которого был выполнен запрос .SAVESTATUS. Совместное использование запросов .SAVESTATUS и .REOPEN требуется для одновременного обращения к большому числу файлов. Файлы открываются по .LOOKUP и параметры их состояния запоминаются по .SAVESTATUS. Когда требуются данные из файла, .REOPEN обеспечивает программе возможность чтения этих данных. Не является обязательным выполнение .REOPEN на том же канале, на котором были выполнены .LOOKUP и .SAVESTATUS.

Формат макрокоманды:

.REOPEN AREA,CHAN,CBLK

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,6
               .WORD   CBLK

Пример см. в описании запроса .SAVESTATUS.

5.1.9. .SAVESTATUS

Запрос .SAVESTATUS запоминает пять слов информации о состоянии канала в указанной пользователем области памяти. Эти слова содержат полную информацию, которая требуется операционной системе для точного определения файла. После выполнения .SAVESTATUS указанный канал освобождается. Если необходимо получить данные по этому каналу, то используется запрос .REOPEN. Запрос .SAVESTATUS может использоваться в том случае, если файл был открыт по .LOOKUP. Если был использован .ENTER, то .SAVESTATUS игнорируется и генерируется ошибка. Запрос .SAVESTATUS недопустим в операциях с файлами, которые находятся на магнитной ленте.

Запросы .SAVESTATUS и .REOPEN используются для работы с большим числом файлов при ограниченном числе каналов.

Формат макрокоманды:

.SAVESTATUS AREA,CHAN,CBLK

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,5
               .WORD   CBLK

Пример.

          .TITLE  SAVEST.MAC
          .MCALL  .CSIGEN,.SAVESTATUS,.READW,.WRITW,.PRINT
          .MCALL  .PURGE,.REOPEN,.CLOSE,.EXIT
          ERRBYT = 52
  START:  .CSIGEN #DSPACE,#DEFEXT ;ВВОД КОМАНДНОЙ СТРОКИ
          MOV     #3,R4           ;ВХОДНОЙ КАНАЛ
          MOV     #AREA,R3        ;УКАЗАТЕЛЬ НА БЛОК
                                  ;СОСТОЯНИЯ КАНАЛА
          MOV     #SAVBLK,R5
  1¤:     .SAVEST R3,R4,R5        ;СОХРАНИТЬ ИНФОРМАЦИЮ
                                  ;О КАНАЛЕ
          BCS     2¤
          ADD     #12,R5          ;УКАЗАТЕЛЬ НА СЛЕДУЮЩИЙ
                                  ;БЛОК ИНФОРМАЦИИ
          INC     R4
          CMP     #8.,R4          ;ВХОДНЫЕ ФАЙЛЫ ВСЕ?
          BGE     1¤              ;НЕТ
  2¤:     MOV     #SAVBLK,R5
          BEQ     7¤
  4¤:     .REOPEN R3,#3,R5        ;ПОВТОРНО ИСПОЛЬЗОВАТЬ
                                  ;КАНАЛ 3
          CLR     BLK
  5¤:     .READW  R3,#3,#BUFF,#256.,BLK ;ЧИТАТЬ БЛОК
          BCC     6¤
          TSTB    @#ERRBYT        ;КОНЕЦ ФАЙЛА?

          BNE     8¤
          .PURGE  #3              ;ОСВОБОДИТЬ КАНАЛ
          ADD     #12,R5
          TST     @R5             ;ПОСЛЕДНИЙ ФАЙЛ?
          BNE     4¤
          .CLOSE  #0              ;ЗАКРЫТЬ ВЫХ.КАНАЛ
          .PRINT  #DONE
          .EXIT

  6¤:     .WRITW  R3,#0,#BUFF,#256.,WBLK ;ЗАПИСАТЬ БЛОК
          INC     WBLK
          INC     BLK
          BCC     5¤
          MOV     #WERR,R0
          BR      9¤
  7¤:     MOV     #NOIMP,R0
          BR      9¤
  8¤:     MOV     #RERR,R0
  9¤:     .PRINT
          .EXIT

  AREA:   .BLKW   5
  BLK:    .WORD   0
  WBLK:   .WORD   0
  SAVBLK: .BLKW   30.
  DEFEXT: .WORD   0,0,0,0
  NOIMP:  .ASCIZ  /НЕТ БОЛЬШЕ ВХОДНЫХ ФАЙЛОВ/
  WERR:   .ASCIZ  /ОШИБКА ЗАПИСИ/
  RERR:   .ASCIZ  /ОШИБКА ЧТЕНИЯ/
  DONE:   .ASCIZ  /КОНЕЦ ПРОГРАММЫ/
          .EVEN
  BUFF:   .BLKW   256.
  DSPACE  =.

          .END    START

5.2. Программные запросы для организации ввода-вывода данных

5.2.1. .READ, .READC, .READW

Система ФОДОС-2 предусматривает три режима выполнения операций ввода-вывода:

.READ /.WRITE

.READC/.WRITC

.READW/.WRITW

При использовании запросов .READ и .READC должны быть определены дополнительные элементы для очереди ввода-вывода.

Если запросы READ/C/W используются для обмена информацией между заданиями, то размер буфера (BUF) должен на одно слово превышать число слов для чтения (WCNT) т.к. первое слово буфера (BUF) будет содержать действительное количество переданных слов.

Запрос .READ используется для передачи определённого количества слов по указанному каналу в буфер памяти. Управление передаётся программе пользователя немедленно после начала выполнения запроса .READ. После завершения передачи данных никаких действий не происходит.

Формат макрокоманды:

.READ AREA,CHAN,BUF,WCNT,BLK

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,10
               .WORD   BLK
               .WORD   BUF
               .WORD   WCNT
               .WORD   1

Пример.

          .TITLE  READ.MAC
  ;ПРИМЕР ИСПОЛЬЗОВАНИЯ ЗАПРОСОВ .READ,.WRITE.
          .MCALL  .READ,.WRITE,.CLOSE,.PRINT,.CSIGEN
          .MCALL  .WAIT,.SRESET,.EXIT
          ERRBYT = 52
          .ENABL  LSB
  START:  .CSIGEN #DSPACE,#DEFEXT ;ВВОД КОМАНДНОЙ СТРОКИ
          MOV     #AREA,R5
          CLR     IOBLK
  1¤:     .READ   R5,#3   ;ЧИТАТЬ С 0-ГО БЛОКА
          BCS     6¤      ;ОШИБКА ЧТЕНИЯ
          ;       .
          BIT     #1,IOBLK
          BNE     2¤
          .PRINT  #MES
          ;       .
  2¤:     .WAIT   #3      ;ЖДАТЬ ЗАВЕРШЕНИЯ ОПЕРАЦИИ
          BCS     5¤
          .WRITE  R5,#0   ;ЗАПИСАТЬ БЛОК
          BCS     3¤
          INC     IOBLK
          ;       .
          .WAIT   #0      ;ЖДАТЬ ЗАВЕРШЕНИЯ ОПЕРАЦИИ
          BCC     1¤
  3¤:     MOV     #WERR,R0
  4¤:     .PRINT
          BR      7¤
  5¤:     MOV     #RERR,R0
          BR      4¤
  6¤:     TSTB    @#ERRBYT
          BNE     5¤
          .PRINT  #MES1
          .CLOSE  #0
  7¤:     .SRESET         ;УДАЛИТЬ ЗАГРУЖЕННЫЙ ДРАЙВЕР
          .EXIT
  AREA:   .WORD   0
  IOBLK:  .WORD   0
          .WORD   BUFF
          .WORD   256.
          .WORD   0
  BUFF:   .BLKW   256.
  DEFEXT: .WORD   0,0,0,0
  MES1:   .ASCIZ  /ОПЕРАЦИЯ ВВОДА-ВЫВОДА ЗАВЕРШЕНА/
  MES:    .ASCIZ  <15><12>/ВЫПОЛНЕНИЕ ПРОГРАММЫ ПРОДОЛЖАЕТСЯ/
  WERR:   .ASCIZ  /ОШИБКА .WRITE/
  RERR:   .ASCIZ  /ОШИБКА .READ/
          .EVEN
  DSPACE  =.

          .END    START

Если ввод выполняется с терминала и BLK=0, то на терминале печатается "^" (код 136).

Когда программе пользователя нужно выполнить чтение данных, может быть использован запрос .WAIT. Это гарантирует то, что данные будут прочитаны полностью. Если во время передачи данных произошла ошибка, запрос .WAIT сообщает о ней.

Запрос .READC передаёт определённое количество слов по указанному каналу в память. Управление программе пользователя будет передано сразу после начала выполнения .READC. Попытка чтения данных после конца файла вызывает передачу управления вызывающей программе с установлением C-разряда и записью нуля в байт ошибок (52-байт). После выполнения .READC управление будет передано подпрограмме завершения, адрес, который указан в запросе. Если в подпрограмме завершения выполняется команда RTS PC, то управление возвращается программе пользователя.

Формат макрокоманды:

.READC AREA,CHAN,BUF,WCNT,CRTN,BLK

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,10
               .WORD   BLK
               .WORD   BUF
               .WORD   WCNT
               .WORD   CRTN

При запуске подпрограммы завершения справедливо следующее:

1. регистр R0 содержит слово состояния канала; если в R0 установлен разряд 0, то произошла аппаратная ошибка во время передачи данных;
2. регистр R1 содержит номер канала для операции; эта информация необходима, когда одна и та же подпрограмма завершения используется в нескольких операциях.

Пример.

          .TITLE  READC.MAC
  ;ПРИМЕР ИСПОЛЬЗОВАНИЯ ЗАПРОСОВ .READC,.WRITC.
          .MCALL  .READC,.WRITC,.CSIGEN,.PRINT
          .MCALL  .CLOSE,.WAIT,.SRESET,.EXIT
          ERRBYT  = 52
          .ENABL  LSB
  START:  .CSIGEN #DSPACE,#DEFEXT ;ВВОД КОМАНДНОЙ СТРОКИ
          CALL    IOXFER
          .PRINT  #MES
          MOV     #-1,R5
  1¤:     DEC     R5
          BNE     1¤
          TSTB    EOF
          BEQ     1¤              ;0 - ОШИБКА ЗАПИСИ
          BLT     RERR            ;<0- ОШИБКА ЧТЕНИЯ
          .CLOSE  #0              ;>0- КОНЕЦ ФАЙЛА
          MOV     #DONE,R0
          BR      EXIT
  WERR:   MOV     #WRERR,R0
          BR      EXIT
  RERR:   MOV     #RDERR,R0
  EXIT:   .PRINT
          .SRESET                 ;УДАЛИТЬ ЗАГРУЖЕННЫЕ
                                  ;ДРАЙВЕРЫ
          .EXIT

  WRDONE: .WAIT   #0
          BCS     3¤
  IOXFER: .READC  #AREA,#3,,,#4¤  ;ЧИТАТЬ БЛОК
          BCC     7¤
          TSTB    @#ERRBYT        ;КОНЕЦ ФАЙЛА?
          BEQ     6¤              ;ДА
  2¤:     DECB    EOF
  3¤:     DECB    EOF
          RETURN
  4¤:     .WAIT   #3
          BCS     2¤
          .WRITC  #AREA,#0,,,#WRDONE ;ЗАПИСАТЬ БЛОК
          BCS     3¤
  5¤:     INC     BLOK
          RETURN
  6¤:     INCB    EOF
  7¤:     RETURN

  AREA:   .WORD   0       ;БЛОК АРГУМЕНТОВ EMT
  BLOK:   .WORD   0       ;НОМЕР БЛОКА
          .WORD   BUFF    ;АДРЕС БУФЕРА
          .WORD   256.    ;СЧЕТЧИК СЛОВ
          .WORD   0       ;АДРЕС ПОДПРОГРАММЫ ЗАВЕРШЕНИЯ
  BUFF:   .BLKW   256.
  DEFEXT: .WORD   0,0,0,0
  DONE:   .ASCIZ  /КОНЕЦ ПРОГРАММЫ/
  MES:    .ASCIZ  /ВЫПОЛНЕНИЕ ПРОГРАММЫ ПРОДОЛЖАЕТСЯ/
  WRERR:  .ASCIZ  /ОШИБКА .WRITC/
  RDERR:  .ASCIZ  /ОШИБКА .READC/
  EOF:    .BYTE   0
          .EVEN
  DSPACE  =.

          .END    START

Запрос .READW передаёт определённое количество слов по указанному каналу в память. Управление передаётся программе пользователя после выполнения запроса .READW или при обнаружении ошибки.

Формат макрокоманды:

.READW AREA,CHAN,BUF,WCNT,BLK

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,10
               .WORD   BLK
               .WORD   BUF
               .WORD   WCNT
               .WORD   0

Если после завершения запроса будет установлен C-разряд, то это указывает на то, что на канале произошла аппаратная ошибка. Если ошибки не было, то данные находятся в памяти, начиная с указанного адреса. В режиме FB одно из заданий может выполняться в то время как другое задание ожидает завершения операции.

Пример.

          .TITLE  READW.MAC
  ;ПРИМЕР ИСПОЛЬЗОВАНИЯ ЗАПРОСОВ .READW,.WRITW.
          .MCALL  .CSIGEN,.READW,.WRITW,.PRINT,.CLOSE
          .MCALL  .SRESET,.EXIT

          ERRBYT = 52

  START:  .CSIGEN #DSPACE,#DEFEXT
          CLR     IOBLK
          MOV     #AREA,R5
  READ:   .READW  R5,#3
          BCC     2¤
          TSTB    @#ERRBYT
          BEQ     3¤
          MOV     #RERR,R0
  1¤:     .PRINT
          BR      4¤
  2¤:     .WRITW  R5,#0
          INC     IOBLK
          BCC     READ
          MOV     #WERR,R0
          BR      1¤
  3¤:     .CLOSE  #0
          .PRINT  #DONE
  4¤:     .SRESET
          .EXIT

  DEFEXT: .WORD   0,0,0,0
  AREA:   .WORD   0
  IOBLK:  .WORD   0
          .WORD   BUFF
          .WORD   256.
          .WORD   0
  BUFF:   .BLKW   256.
  RERR:   .ASCIZ  /ОШИБКА .READW/
  WERR:   .ASCIZ  /ОШИБКА .WRITW/
  DONE:   .ASCIZ  /КОНЕЦ ПРОГРАММЫ/
          .EVEN
  DSPACE  =.

          .END    START

5.2.2. .WRITE, .WRITC, .WRITW

При использовании запросов .WRITE и .WRITC должны быть определены дополнительные элементы для очереди ввода-вывода.

Запрос .WRITE передаёт указанное количество слов из памяти по указанному каналу. Управление программе пользователя передаётся сразу же после того, как запрос будет поставлен в очередь.

Формат макрокоманды:

.WRITE AREA,CHAN,BUF,WCNT,BLK

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,11
               .WORD   BLK
               .WORD   BUF
               .WORD   WCNT
               .WORD   1

Запрос .WRITC передаёт заданное количество слов из памяти по указанному каналу. Управление передаётся программе пользователя немедленно после начала выполнения .WRITC. После выполнения запросов, управление будет передано подпрограмме завершения. По команде RTS PC управление возвращается программе пользователя.

Формат макрокоманды:

.WRITC AREA,CHAN,BUF,WCNT,CRTN,BLK

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,11
               .WORD   BLK
               .WORD   BUF
               .WORD   WCNT
               .WORD   CRTN

Запрос .WRITW передаёт заданное количество слов из памяти по указанному каналу. Управление передаётся программе пользователя после завершения .WRITW.

Формат макрокоманды:

.WRITW AREA,CHAN,BUF,WCNT,BLK

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,10
               .WORD   BLK
               .WORD   BUF
               .WORD   WCNT
               .WORD   0

5.2.3. .RCVD, .RCVDC, .RCVDW (режим FB, XM)

Существуют три формы запроса получения данных, которые используются вместе с запросами .SDAT. Запросы .RCVD аналогичны запросам .READ, но в отличие от них осуществляют приём данных из другой программы, а не с устройства. При использовании запросов .RCVD и .RCVDC должны быть определены дополнительные элементы для очереди ввода-вывода.

Запрос .RCVD используется для получения данных или сообщений, посылаемых другой программой. Управление вызывающей программе передаётся сразу же после начала выполнения запроса .RCVD. При необходимости, с .RCVD используется запрос .MWAIT, который задерживает выполнение программы до окончания операции.

Формат макрокоманды:

.RCVD AREA,BUF,WCNT

Формат блока аргументов EMT:

       AREA:   .BYTE   0,26
               .WORD   <ЗАРЕЗЕРВИРОВАНО>
               .WORD   BUF
               .WORD   WCNT
               .WORD   1

После выполнения монитором запроса .RCVD, первое слово буфера (BUF) будет содержать действительное количество переданных слов. Таким образом, область памяти для приёма данных должна быть, по крайней мере, на одно слово больше размера передаваемого сообщения.

Комбинация .SDAT/.RCVD может быть использована для передачи как нескольких слов, так и целого буфера. Операция по запросу .RCVD заканчивается только после выполнения .SDAT из другой программы.

Пример использования .RCVD см. в описании запроса .MWAIT.

Запрос .RCVDC осуществляет приём данных и запускает подпрограмму завершения после получения сообщения (аналогично .READC).

Формат макрокоманды:

.RCVDC AREA,BUF,WCNT,CRTN

Формат блока аргументов EMT:

    AREA:   .BYTE   0,26
            .WORD   <ЗАРЕЗЕРВИРОВАНО>
            .WORD   BUF
            .WORD   WCNT
            .WORD   CRTN

Запрос .RCVDW осуществляет приём данных и ожидает окончания операции. Выполнение вызывающей программы задерживается до окончания передачи сообщения другой программой.

Формат макрокоманды:

     .RCVDW AREA,BUF,WCNT

Формат блока аргументов EMT:

       AREA:   .BYTE   0,26
               .WORD   <ЗАРЕЗЕРВИРОВАНО>
               .WORD   BUF
               .WORD   WCNT
               .WORD   0

Как и в .RCVD, первое слово буфера для .RCVDC и .RCVDW будет содержать действительное количество переданных слов.

Пример использования .RCVDW см. в описании запроса .CHCOPY.

5.2.4. .SDAT, .SDATC, .SDATW (режим FB, XM)

Запросы .SDAT, .SDATC, .SDATW используются вместе с запросами .RCVD, .RCVDC, .RCVDW для передачи сообщений или данных между программами под управлением мониторов FB или XM.

Запросы .SDAT, .SDATC, .SDATW аналогично запросам .WRITE, .WRITC, .WRITW, только осуществляют передачу данных не на устройство, а другой программе. При использовании запросов .SDAT и .SDATC должны быть определены дополнительные элементы для очереди ввода-вывода.

.SDAT

Формат макрокоманды:

.SDAT AREA,BUF,WCNT

Формат блока аргументов EMT:

       AREA:   .BYTE   0,25
               .WORD   <ЗАРЕЗЕРВИРОВАНО>
               .WORD   BUF
               .WORD   WCNT
               .WORD   1

Пример использования .SDAT см. в описании запроса .MWAIT.

.SDATC

Формат макрокоманды:

.SDATC AREA,BUF,WCNT,CRTN

Формат блока аргументов EMT:

       AREA:   .BYTE   0,25
               .WORD   <ЗАРЕЗЕРВИРОВАНО>
               .WORD   BUF
               .WORD   WCNT
               .WORD   CRTN

.SDATW

Формат макрокоманды:

.SDATW AREA,BUF,WCNT

Формат блока аргументов EMT:

       AREA:   .BYTE   0,25
               .WORD   <ЗАРЕЗЕРВИРОВАНО>
               .WORD   BUF
               .WORD   WCNT
               .WORD   0

Пример использования .SDATW см. в описании запроса .CHCOPY.

5.2.5. .TTYIN, .TTINR

Запросы .TTYIN и .TTINR используются для передачи символов с терминала в программу пользователя.

Макрорасширение для .TTYIN:

             EMT 340
             BCS .-2

Макрорасширение для .TTINR:

             EMT 340

Запрос .TTYIN ожидает подачу символа или строки символов, в то время как пользователь может или ожидать, или продолжать выполнение программы, используя .TTINR. Если по завершению выполнения .TTINR устанавливает C-разряд, то это значит, что в буфере терминала символ отсутствует (пользователь ещё не напечатал его). В режимах FB, XM и SJ (без мультитерминальной поддержки) .TTINR не устанавливает C-разряд, если не установлен 6-ой разряд в слове состояния задания (ССЗ).

Существуют два режима ввода с терминала. Режим ввода определяется содержимым 12-го разряда в ССЗ. Если содержимое 12-го разряда ноль, то говорят об общем режиме ввода-вывода. В этом режиме выполняются следующие действия:

1. монитор обеспечивает "эхо" всем символам, вводимым с терминала;
2. стирание символов и строк осуществляется с помощью команд ЗБ и СУ/U соответственно;
3. для передачи символов программе необходимо подать <ВК>, <ПС> или команды СУ/Z или СУ/C; возврат каретки и перевод строки также передаются программе пользователя.

Если 12-ый разряд в ССЗ равен единице, то устанавливается специальный режим ввода-вывода. В этом режиме выполняются следующие действия:

1. монитор не выдаёт "эхо" символам, вводимым с терминала, кроме СУ/C и СУ/D;
2. СУ/U и ЗБ не выполняют своих функций;
3. символы сразу же передаются программе пользователя.

В специальном режиме программа пользователя должна сама выполнять печать вводимых символов, если это необходимо (исключение составляют СУ/C и СУ/D).

12-ый разряд в ССЗ должен устанавливаться программой пользователя. Этот разряд очищается, если управление передаётся монитору.

Действия СУ/F, СУ/B и СУ/X не зависят от содержимого 12-го разряда, если ранее не была подана команда SET TT NOFB.

Команды СУ/S и СУ/Q выполняются монитором, если только в режиме FB(XM) ранее не была выполнена команда SET TT NOPAGE.

Если в режиме FB (XM) сделан запрос ввода, а символа нет в наличии, то выполнение программы блокируется до тех пор, пока в буфере ввода не появится символ. Это справедливо для .TTYIN и .TTINR и не зависит от режима ввода. Для того чтобы продолжить выполнение программы (и обеспечить установку C-разряда в случае отсутствия символа в буфере ввода) необходимо установить перед .TTINR 6-ой разряд в ССЗ. 6-ой разряд очищается после окончания выполнения программы.

Вводимые по .TTYIN, .TTINR символы можно редактировать с помощью SL, если предварительно были поданы команды SET SL ON и SET SL TTYIN и содержимое 4-го и 12-го разрядов ССЗ равны нулю.

При редактировании посредством SL, содержимое 6-го разряда ССЗ не существенно, и выполнение запроса .TTINR будет завершено только после завершения операции редактирования.

Примечание. Запрос .TTYIN не обслуживает косвенные файлы. Для этой цели необходимо воспользоваться запросом .GTLIN. По .TTYIN невозможно получить символ из косвенного файла.

Формат макрокоманды:

.TTYIN CHAR

.TTINR

Пример использования .TTYIN, .TTINR см. в описании запросов .TTYOUT, .TTOUTR.

5.2.6. .TTYOUT, .TTOUTR

Запросы .TTYOUT, .TTOUTR используются для передачи символов из R0 в буфер терминала. Действия этих запросов аналогичны действиям запросов .TTYIN, .TTINR. Если буфер терминала заполнен, то запрос .TTYOUT ожидает появления в буфере свободного места для выводимого символа, тогда как .TTOUTR не ожидает свободного места и символ, находящийся в R0, на терминал не выводится. Если после завершения .TTOUTR установлен C-разряд, то это говорит о том, что в буфере нет свободного места, и что символ не был выведен на терминал. В режимах FB, XM запрос .TTOUTR не устанавливает C-разряд. В этом случае, выполнение программы блокируется до появления в буфере свободного места. Для того чтобы продолжить выполнение программы и обеспечить установку C-разряда, необходимо в ССЗ установить 6-ой разряд.

Примечание. Если в основном задании установлен 6-ой разряд в ССЗ, то запросы .TTYIN и .TTYOUT будут вызывать блокировку фонового задания. Заметим, что каждое задание в основном или фоновом режиме имеет свое собственное ССЗ и поэтому они могут использовать различные режимы работы терминала независимо друг от друга.

Формат макрокоманды:

.TTYOUT CHAR

.TTOUTR

Пример.

          .TITLE  TTIO.MAC
          .MCALL  .TTYIN,.TTYOUT,.TTINR,.TTOUTR,.EXIT
          JSW     = 44       ;СЛОВО СОСТОЯНИЯ ЗАДАНИЯ
  START:  MOV     #BUFFER,R1
          CLR     R2
          BIS     #100,@#JSW ;УСТАНОВИТЬ 6 РАЗРЯД
  INLOOP: .TTINR             ;ВВЕСТИ СИМВОЛ С ТТ:
          BCS     NOCHR
  CHRIN:  MOVB    R0,(R1)+   ;ПЕРЕСЛАТЬ СИМВОЛ В БУФЕР
          INC     R2
          CMPB    R0,#12
          BNE     INLOOP
          MOV     #BUFFER,R1
  OUTLOOP:MOVB    (R1),R0    ;ПЕРЕСЛАТЬ СИМВОЛ В R0
          .TTOUTR            ;ВЫВЕСТИ СИМВОЛ НА ТТ:
          BCS     NOROOM
  CHROUT: DEC     R2
          BEQ     START
          INC     R1
          BR      OUTLOOP    ;ПЕЧАТАТЬ СЛЕДУЮЩИЙ СИМВОЛ
  NOCHR:  .TTINR
          BCC     CHRIN      ;ЕСТЬ СИМВОЛ?
          ;       .
          ;       .
          ;       .
          BR      NOCHR

  NOROOM: MOVB    (R1),R0
          .TTOUTR
          BCC     CHROUT     ;ПРИ НАЛИЧИИ СИМВОЛА -
                             ;ПЕЧАТАТЬ ЕГО
          ;       .
          ;       .
          ;       .
          BIC     #100,@#JSW ;ОЧИСТИТЬ 6 РАЗРЯД И
          .TTYOUT (R1)       ;ПЕЧАТАТЬ СИМВОЛ
          BIS     #100,@#JSW
          BR      CHROUT

  BUFFER: .BLKB   128.
          .END    START

5.2.7. .PRINT

Запрос .PRINT вызывает печать строки символов КОИ-7 на системном терминале. В режимах FB, XM каждому сообщению предшествует побуждающий знак В> или F>, в зависимости от того, какое задание его печатает (В> - фоновое, F> - основное). Это происходит в случае переключения системного терминала на обслуживание другого задания.

Если ввод на терминал выполняется системным заданием, то в качестве побуждающего знака печатается имя системного задания.

Строка текста, которая выводится на печать, может оканчиваться как нулевым (0) байтом, так и байтом 200. В первом случае, в отличие от второго, вывод автоматически заканчивается <ВК> и <ПС>.

Управление возвращается программе пользователя после того как все символы будут записаны в буфер вывода монитора.

Основное задание печатает сообщение сразу же, независимо от состояния фонового задания.

Таким образом, для печати срочных сообщений должен использоваться запрос .PRINT, а не .TTYIN или .TTYOUT.

Если фоновое задание печатает побуждающий знак и звёздочку, то системный терминал будет принадлежать ему и запросы .TTYOUT из основного задания выполняться не будут, пока для фонового не будет выполнен <ВК>.

Формат макрокоманды:

.PRINT ADDR

Пример.

          .TITLE  PRINT.MAC
  ;В ЭТОМ ПРИМЕРЕ ЗАПРОС .PRINT ИСПОЛЬЗУЕТСЯ ДЛЯ ПЕЧАТИ
  ;СИМВОЛОВ, ВВОДИМЫХ С ТЕРМИНАЛА.
          .MCALL  .GTLIN,.PRINT,.EXIT
  START:  .GTLIN  #BUFF,#PROMPT   ;ВВОД СИМВОЛОВ С ТЕРМИНАЛА
          TSTB    BUFF            ;СТРОКА ПУСТАЯ?
          BEQ     1¤              ;ДА
          .PRINT  #BUFF           ;НЕТ-ПЕЧАТЬ СТРОКИ
          CLRB    BUFF
          BR      START
  1¤:     .EXIT
  BUFF:   .BLKW   41.
  PROMPT: .ASCII  /ВВЕДИТЕ СТРОКУ :   /<200>

          .END START

5.2.8. .MTIN

Запрос .MTIN является мультитерминальной формой запроса .TTYIN. Запрос .MTIN пересылает один или более символов из буфера ввода монитора в буфер, указанный пользователем. Терминал должен быть логически связан с текущим заданием. Если запрос выполнен успешно, то модифицированный адрес буфера пользователя будет записан в R0. Если разряд TCBIT установлен в слове M.TSTS, то запрос .MTIN устанавливает C-разряд и передаёт управление вызывающей программе, если ввод с терминала невозможен (т.е. нет строки, если разряд TTSPC очищен или нет символа в буфере ввода, если разряд TTSPC установлен). В противном случае, .MTIN будет ожидать операции ввода и, тем самым, выполнение задания будет приостановлено.

Формат макрокоманды:

.MTIN AREA,ADDR,UNIT[,CHRCNT]

ФОРМАТ БЛОКА АРГУМЕНТОВ EMT:

       AREA:   .BYTE   2,37
               .WORD   ADDR
               .BYTE   UNIT,CHRCNT

5.2.9. .MTOUT

Запрос .MTOUT является мультитерминальной формой запроса .TTYOUT. Запрос .MTOUT пересылает один или более символов из буфера пользователя в буфер вывода терминала. Терминал должен быть логически связан с заданием. Модифицированный адрес буфера пользователя будет записан в R0, если запрос выполнен успешно. Если в буфере вывода нет свободного места и разряд TCBIT установлен в слове M.TSTS, то .MTOUT устанавливает C-разряд и передаёт управление вызывающей программе. Если разряд TCBIT очищен, выполнение задания приостанавливается до тех пор, пока не появится свободное место в буфере вывода.

Формат макрокоманды:

.MTOUT AREA,ADDR,UNIT[,CHRCNT]

Формат блока аргументов EMT:

       AREA:   .BYTE   3,37
               .WORD   ADDR
               .BYTE   UNIT,CHRCNT

5.2.10. .MTPRNT

Запрос .MTPRNT является мультитерминальной формой запроса .PRINT. Он осуществляет вывод одной или нескольких строк символов на указанный терминал.

Формат макрокоманды:

.MTPRNT AREA,ADDR,UNIT

Формат блока аргументов EMT:

    AREA:   .BYTE   7,37
            .WORD   ADDR
            .BYTE   UNIT

5.2.11. .SPFUN

Запрос .SPFUN используется главным образом драйверами устройств для выполнения специальных функций, зависящих от этих устройств.

Формат макрокоманды:

.SPFUN AREA,CHAN,FUNC,BUF,WCNT,BLK[,CRTN]

Аргументы CHAN, BLK, WCNT те же, что и в запросах .READ/.WRITE. Они используются только тогда, когда необходимо произвести запись на магнитную ленту с расширенным межфайловым промежутком.

Формат блока аргументов EMT:

       AREA:   .BYTE   CHAN,32
               .WORD   BLK
               .WORD   BUF
               .WORD   WCNT
               .BYTE   377,FUNC
               .WORD   CRTN

В табл. 9 приводятся функции запроса .SPFUN и соответствующие им коды.

Для использования запроса .SPFUN необходимо, чтобы драйвер соответствующего устройства находился в памяти и канал был связан с файлом по запросу .LOOKUP.

Пример.

          .TITLE  SPFUN.MAC
  ;ПРИМЕР ИСПОЛЬЗОВАНИЯ ЗАПРОСА .SPFUN.
          .MCALL  .SPFUN,.FETCH,.LOOKUP,.PRINT,.CLOSE,.EXIT
  START:  .FETCH  #DSPC,#MT       ;ЗАГРУЗИТЬ ДРАЙВЕР МТ:
          BCS     1¤
          .LOOKUP #AREA,#4,#MT    ;ОТКРЫТЬ КАНАЛ
          BCS     2¤
          .SPFUN  #AREA,#4,#373,#0;ПЕРЕМОТКА ДО ТОЧКИ
                                  ;ЗАГРУЗКИ
          .BCS    3¤
          .CLOSE  #4
          .EXIT
  1¤:     MOV     #FERR,R0
          BR      5¤
  2¤:     MOV     #LKERR,R0
          BR      5¤
  3¤:     MOV     #SPERR,R0
  5¤:     .PRINT
          .EXIT
  AREA:   .WORD   0
  MT:     .RAD50  /MT /
          .WORD   0,0,0
  FERR:   .ASCIZ  /ОШИБКА .FETCH/
  LKERR:  .ASCIZ  /ОШИБКА .LOOKUP/
  SPERR:  .ASCIZ  /ОШИБКА .SPFUN/
          .EVEN
  DSPC    =.
          .END    START

5.3. Запросы общего назначения

5.3.1. .CDFN

Запрос .CDFN используется для переопределения числа каналов ввода-вывода. Каждое задание независимо от того является ли оно основным или фоновым, первоначально обеспечивается 16₍₁₀₎ каналами ввода-вывода (от 0 до 15). Запрос .CDFN позволяет увеличить число каналов до 255₍₁₀₎ (от 0 до 254). Канал с номером 255 используется монитором. Область памяти для новых каналов определяется в пределах программы пользователя. Под каждый канал ввода-вывода отводится пять слов (семь слов для монитора XM). В режиме XM область памяти для дополнительных каналов, указанных в запросе .CDFN, должна располагаться в нижних 28К оперативной памяти. Рекомендуется, чтобы запрос .CDFN выполнялся в начале программы перед операциями ввода-вывода. Если в программе используется более одного запроса .CDFN, то области каналов для них не должны перекрывать друг друга, но могут иметь один и тот же начальный адрес. Два запроса .SRESET и .HRESET восстанавливают первоначальное число каналов (16₍₁₀₎). Следовательно, все запросы .CDFN должны выполняться повторно после использования .SRESET или .HRESET.

Заметим, что запрос .CDFN определяет новые каналы. Область памяти для ранее определённых каналов не используется. Так, запрос .CDFN для 20₍₁₀₎ каналов ввода-вывода (в то время как 16 первоначальных каналов уже определены) создаёт 20 новых каналов ввода-вывода. Область для 16-ти первоначальных каналов не используется, но содержимое старых каналов будет скопировано в новые.

Для программы с оверлейной структурой 15-ый канал используется оверлейным драйвером и не должен изменяться.

Формат макрокоманды:

.CDFN AREA,ADDR,NUM

Формат блока аргументов EMT:

       AREA:   .BYTE   0,15
               .WORD   ADDR
               .WORD   NUM

Пример.

          .TITLE  CDFN.MAC
  ; В ЭТОМ ПРИМЕРЕ ЗАПРОС .CDFN ИСПОЛЬЗУЕТСЯ ДЛЯ
  ; ОПРЕДЕЛЕНИЯ 32. НОВЫХ КАНАЛОВ.

          .MCALL  .CDFN,.PRINT,.EXIT,.HRESET

  START:  .CDFN   #AREA,#CHAN,#255.   ;ОПРЕДЕЛИТЬ 32.КАНАЛА
          BCC     1¤
          .PRINT  #MSG1               ;ПЕЧАТЬ СООБЩЕНИЯ
          .EXIT                       ;ВЫХОД ИЗ ПРОГРАММЫ
  1¤:     .PRINT  #MSG2               ;ПЕЧАТЬ СООБЩЕНИЯ
          .HRESET
          .EXIT                       ;ВЫХОД ИЗ ПРОГРАММЫ

  AREA:   .BLKW   3                   ;БЛОК АРГУМЕНТОВ EMT
  CHAN:   .BLKW   5*255.              ;ОБЛАСТЬ ДЛЯ КАНАЛОВ

  MSG1:   .ASCIZ  /ОШИБКА .CDFN/
  MSG2:   .ASCII  /ОПРЕДЕЛЕНЫ 32. НОВЫХ КАНАЛА/<15><12>
          .ASCIZ  /ВОЗВРАТ К 16. КАНАЛАМ/
          .EVEN

          .END    START

5.3.2. .CHAIN

Запрос .CHAIN позволяет одной фоновой программе инициировать выполнение другой фоновой программы без вмешательства оператора. Этот процесс может повторяться, и позволяет организовать последовательное выполнение большого числа программ.

Ячейки 500-507 должны содержать имя устройства и имя файла (в кодах RADIX-50), который необходимо вызвать. Ячейки 510-777 используются для передачи информации между последовательно выполняемыми программами.

Формат макрокоманды:

.CHAIN

Примечания:

1. Содержимое областей оперативной памяти, за исключением области памяти которую занимает резидентный монитор и ячеек 500-777, может изменяться после выполнения .CHAIN; если .CHAIN выполняется из виртуального задания, то содержимое ячеек 500-777 не сохраняется.
2. Каналы ввода-вывода остаются открытыми после выполнения запроса .CHAIN для использования новой программой. Однако, каналы ввода-вывода, открытые по запросу .CDFN не могут использоваться. Так как по запросу .CHAIN монитор восстанавливает первоначальное число каналов (16₍₁₀₎), то программа, которая оставляет файлы открытыми при выполнении .CHAIN не должна использовать .CDFN. Нерезидентные драйверы устройств удаляются из памяти при выполнении .CHAIN, поэтому они должны быть вновь загружены новой программой.
3. По 8-ому разряду ССЗ программа может определить, как она была загружена - по запросу .CHAIN или по команде RUN. Разряд устанавливается во время выполнения программы, если она была загружена с помощью .CHAIN. Если программа, занимающая ячейки от 500 до 777, предназначена для загрузки по запросу .CHAIN, то в ней должен быть установлен 8-ой разряд в ССЗ во время её трансляции. В этом случае, программа будет загружена правильно. Если разряд не установлен, ячейки 500-777, содержимое которых сохраняется от предыдущей программы, могут вызвать неправильную работу новой программы.
4. Для запроса .CHAIN характерны те же ошибки, что и для команды RUN.

Пример.

  ; В ЭТОМ ПРИМЕРЕ ПРОГРАММА CHAIN1.SAV ЗАГРУЖАЕТСЯ
  ; ИЗ ПРОГРАММЫ CHAIN.SAV ПОСРЕДСТВОМ ЗАПРОСА .CHAIN

          .TITLE  CHAIN.MAC

          .MCALL  .CHAIN,.TTYIN,.PRINT

  START:  MOV     #500,R1
          MOV     #CHPTR,R2
          .REPT   4
          MOV     (R2)+,(R1)+   ;ИМЯ ФАЙЛА В ЯЧЕЙКИ 500-507
          .ENDR
          .PRINT  #PROMT
  LOOP:   .TTYIN                ;ПЕРЕДАТЬ СИМВОЛЫ С ТТ: В
                                ;ЯЧЕЙКИ 510-777
          MOVB    R0,(R1)+
          CMPB    R0,#12        ;КОНЕЦ СТРОКИ?
          BNE     LOOP          ;НЕТ
          CLRB    @R1
          .CHAIN  ;ЗАПУСК ПРОГРАММЫ CHAIN1
  CHPTR:  .RAD50  /DK/
          .RAD50  /CHAIN1/
          .RAD50  /SAV/
  PROMT:  .ASCII  /ВВЕДИТЕ ДАННЫЕ ДЛЯ ПРОГРАММЫ CHAIN1: /<200>

          .END    START

  ; ПРОГРАММА  CHAIN1

          .TITLE  CHAIN1.MAC

          .MCALL  .PRINT,.EXIT

          JSW = 44
          CHAIN¤ = 400

  STARTC: BIT     #CHAIN¤,@#JSW   ;8 РАЗРЯД УСТАНОВЛЕН?
          BEQ     1¤              ;НЕТ
          .PRINT  #CHAIND         ;ДА - ПЕЧАТЬ СООБЩЕНИЯ
          MOV     #510,R0
          .PRINT                  ;ПЕЧАТЬ СОДЕРЖИМОГО ЯЧЕЕК
                                  ;510-777
          .EXIT
  1¤:     .PRINT  #NOCHN
          .EXIT
  CHAIND: .ASCII  /СОДЕРЖИМОЕ ЯЧЕЕК 510-777 :  /<200>
  NOCHN:  .ASCIZ  /НЕ УСТАНОВЛЕН 8-ОЙ РАЗРЯД !/
          .END    STARTC

5.3.3. .CMKT

Запрос .CMKT аннулирует один или несколько запросов .MRKT.

Формат макрокоманды:

.CMKT AREA,ID[,TIME]

Формат блока аргументов EMT:

       AREA:   .BYTE   0,23
               .WORD   ID

Примечание. Аннулированный запрос .MRKT освобождает соответствующий элемент очереди.

Пример использования .CMKT см. в описании запроса .MRKT.

5.3.4. .CNTXSW (режим FB, XM)

При передаче управления от одного задания другому, монитор выполняет, так называемую, операцию переключения контекста. Она заключается в сохранении системой необходимых параметров для однозначного определения и выполнения задания. Эти параметры включают все регистры общего назначения, ячейки 34-52, а также все регистры ППЗ, если запрос .SFPA выполнялся с отличным от нуля адресом подпрограммы обработки прерывания от ППЗ.

Запрос .CNTXSW используется для определения ячеек памяти, которые будут дополнительно включены в операцию переключения контекста.

Иногда, для обоих заданий необходимо независимое использование определённой ячейки памяти, которая не включена в обычную операцию переключения контекста. Например, если программа использует команду IOT, то она должна установить в векторе 20 адрес своей подпрограммы обработки прерывания по этой команде. А если оба задания - основное и фоновое - используют команду IOT, то вектор 20 должен всегда содержать соответствующий с выполняемым заданием адрес. Это достигается путем включения ячеек 20 и 22 в список адресов запроса .CNTXSW.

Если запрос .CNTXSW указан в программе несколько раз, то монитор использует список адресов последнего из них.

Список адресов .CNTXSW не может быть в области свопинга USR и его нельзя изменять в процессе работы программы.

В режиме XM, запрос .CNTXSW игнорируется для виртуальных заданий, т.к. они не используют память совместно с другими заданиями. Для виртуальных заданий векторы IOT, TRAP, BPT и вектор 250 автоматически включаются монитором XM в операцию переключения контекста, и, следовательно, могут быть использованы другим заданием без .CNTXSW.

Формат макрокоманды:

.CNTXSW AREA,ADDR

Формат блока аргументов EMT:

       AREA:  .BYTE   0,33
              .WORD   ADDR

Пример.

          .TITLE  CNTXSW.MAC
  ; В ЭТОМ ПРИМЕРЕ ЗАПРОС .CNTXSW ИСПОЛЬЗУЕТСЯ ДЛЯ
  ; ВКЛЮЧЕНИЯ ЯЧЕЕК 20,22,177302,177304,177310 В
  ; ОПЕРАЦИЮ ПЕРЕКЛЮЧЕНИЯ КОНТЕКСТА.
          .MCALL  .CNTXSW,.PRINT,.EXIT
  START:  .CNTXSW #AREA,#SWLIST
          BCC     1¤
          .PRINT  #ADDRER
          .EXIT
  1¤:     .PRINT  #CNTOK
          .EXIT

  SWLIST: .WORD   20
          .WORD   22
          .WORD   177302
          .WORD   177304
          .WORD   177310
          .WORD   0

  AREA:   .BLKW   2

  ADDRER: .ASCIZ  /ОШИБКА .CNTXSW /
  CNTOK:  .ASCIZ  /АДРЕСА ВКЛЮЧЕНЫ В ОПЕРАЦИЮ КОНТЕКСТА/

          .END    START

5.3.5. .CSIGEN

Запрос .CSIGEN вызывает работу интерпретатора командной строки (CSI) в общем режиме. В этом режиме CSI осуществляется синтаксический анализ командной строки и выполняет следующие функции:

1. загружает драйверы указанных устройств;
2. выполняет запросы .LOOKUP и/или .ENTER для указанных файлов;
3. записывает в стек информацию о переключателях;
4. выполняет запрос .CLOSE на каналах 0-10₍₈₎.

Область, которая отводится для драйверов устройств, должна быть достаточной для одновременного размещения всех необходимых драйверов. Если этой области недостаточно, то программа пользователя может быть разрушена.

После выполнения запроса .CSIGEN регистр R0 будет указывать на первую свободную ячейку памяти после драйверов устройств.

Когда управление возвращается программе пользователя после выполнения запроса .CSIGEN, все указанные файлы будут открыты для ввода и/или вывода. Три выходных файла будут открыты соответственно на 0,1 и 2-ом каналах; шесть входных - будут связаны с каналами 3-10₍₈₎.

Например, в командной строке

*,LP:=F1,F2

0-ой и 2-ой каналы остаются свободными, 1-й канал связывается с LP:, 3 и 4-й каналы связываются соответственно с файлами F1 и F2 на DK:, каналы 5-10₍₈₎ остаются свободными.

Программа пользователя может определить, открыт или нет канал посредством запроса .WAIT на соответствующем канале, и получить сообщение об ошибке, если канал не открыт.

Переключатели и их аргументы записываются в стек.

Формат макрокоманды:

.CSIGEN DEVSPC,DEFTYP,CSTR[,LINBUF]

Примечания:

1. Блок, адрес которого указан в DEFTYP, в 1-ом слове содержит тип файла для всех входных файлов, во 2, 3 и 4-ом словах - типы файлов соответственно для 0,1 и 2-го выходных файлов. Если в блоке не указан тип файла для определённого канала, соответствующее слово должно содержать нуль. Все типы файлов должны быть записаны в кодах RADIX-50.
2. Запрос CSIGEN автоматически воспринимает командную строку из косвенного файла, если указан ввод с терминала (CSTR=0) и программа, использующая .CSIGEN вызывается через косвенный файл.
3. Аргумент LINBUF предоставляет пользователю возможность восстановления первоначально введённой командной строки.
4. Если ошибка происходит при вводе командной строки с терминала, то CSI печатает сообщение об ошибке на терминале, если при вводе из памяти - устанавливается C-разряд и код ошибки (52-ой байт).

Пример.

          .TITLE  CSIGEN.MAC
  ;ПРИМЕР ПРОГРАММЫ С ИСПОЛЬЗОВАНИЕМ ЗАПРОСА .CSIGEN
  ;ВЫПОЛНЯЕТ КОПИРОВАНИЕ УКАЗАННОГО ФАЙЛА

          .MCALL .CSIGEN,.READW,.WRITW,.CLOSE,.SRESET,.EXIT
          .MCALL .PRINT

          ERRBYT=52

  START:  .CSIGEN #DSPACE,#DEXT   ;ВВЕСТИ КОМАНДНУЮ СТРОКУ
          MOV     R0,BUFF         ;УКАЗАТЕЛЬ НА СВОБОДНУЮ
                                  ;ПАМЯТЬ
          CLR     INBLK           ;НОМЕР БЛОКА
          MOV     #AREA,R5
  READ:   .READW  R5,#3,BUFF,#400,INBLK ;ЧИТАТЬ БЛОК
          BCC     2¤
          TSTB    @#ERRBYT        ;КОНЕЦ ФАЙЛА?
          BEQ     EOF             ;ДА
          MOV     #INERR,R0
  1¤:     .PRINT                  ;ПЕЧАТЬ СООБЩЕНИЯ
          CLR     R0
          .EXIT
  2¤:     .WRITW  R5,#0,BUFF,#400,INBLK ;ЗАПИСАТЬ БЛОК
          BCC     NOERR
          MOV     #WTERR,R0
          BR      1¤
  NOERR:  INC     INBLK           ;УВЕЛИЧИТЬ СЧЁТЧИК И
          BR      READ            ;ЧИТАТЬ СЛЕДУЮЩИЙ БЛОК
  EOF:    .CLOSE  #0              ;КОНЕЦ ФАЙЛА - ЗАКРЫТЬ
          .CLOSE  #3              ;ВХОДНОЙ И ВЫХОДНОЙ
                                  ;КАНАЛЫ
          .SRESET                 ;УДАЛИТЬ ДРАЙВЕРЫ ИЗ
                                  ;ПАМЯТИ
          .EXIT

  DEXT:   .WORD   0,0,0,0
  BUFF:   .WORD   0
  INBLK:  .WORD   0
  AREA:   .BLKW   5

  INERR:  .ASCIZ /ОШИБКА ВВОДА/
  WTERR:  .ASCIZ /ОШИБКА ВЫВОДА/
          .EVEN

  DSPACE  =.

          .END    START

5.3.6. .CSISPC

Запрос .CSISPC вызывает работу CSI в специальном режиме. В этом режиме он осуществляет синтаксический анализ командной строки и передаёт спецификации файлов и переключатели, указанные в ней, программе пользователя. В специальном режиме CSI не выполняет действий, аналогичных функциям запросов .FETCH, .CLOSE, .ENTER, .LOOKUP.

Переключатели и их аргументы пересылаются в стек.

Если программа, использующая .CSISPC, вызывается через косвенный файл и CSTR=0, то .CSISPC автоматически выбирает входную строку из косвенного файла.

Формат макрокоманды:

.CSISPC OUTSPC,DEFTYP[,CSTR][,LINBUF]

Блок, адрес которого указан в OUTSPC, содержит спецификацию для 9 файлов: по 5 слов для каждого из 3-х выходных файлов и по 4 слова для каждого из 6-ти входных файлов. Пять слов для выходного файла имеют следующее содержимое: 1-ое слово - имя устройства; 2 и 3 слова - имя файла; 4-ое слово - тип файла; 5-е слово - длина выходного файла. Если какой-то файл отсутствует, то соответствующие слова блока содержат нули.

Например,

*DX1:LIST.MAC[15]=PC:

после выполнения .CSISPC первые 5 слов для блока, адрес которого указан в OUTSPC, будут иметь следующее значения:

16337  RADIX-50 ДЛЯ DX1
46173  RADIX-50 ДЛЯ LIS
76400  RADIX-50 ДЛЯ T
50553  RADIX-50 ДЛЯ MAC
00017  ДЛИНА ФАЙЛА

Первые 4 слова для спецификаций входных файлов (начиная с адреса OUTSPC+36) будут выглядеть так:

62170 RADIX-50 ДЛЯ PC
0     ИМЯ ФАЙЛА НЕ УКАЗАНО
0
0

Если при вводе с терминала произошла ошибка, USR не печатает на терминале сообщение об ошибке, а устанавливает C-разряд в ССП.

Пример.

          .TITLE  CSISPC.MAC

  ;В ЭТОМ ПРИМЕРЕ ИСПОЛЬЗУЕТСЯ СПЕЦИАЛЬНЫЙ РЕЖИМ
  ;РАБОТЫ ИНТЕРПРЕТАТОРА КОМАНДНОЙ СТРОКИ.
  ;ЗАПРОС .DSTATUS ОПРЕДЕЛЯЕТ ЗАГРУЖЕН ЛИ ДРАЙВЕР
  ;ВЫХОДНОГО УСТРОЙСТВА И, ЕСЛИ НЕТ, ТО ИСПОЛЬЗУЕТСЯ
  ;ЗАПРОС .FETCH ДЛЯ ЗАГРУЗКИ ДРАЙВЕРА В ПАМЯТЬ.
  ;ЗАТЕМ УКАЗАНЫЙ ФАЙЛ УДАЛЯЕТСЯ ПО ЗАПРОСУ .DELETE.

          .MCALL  .CSISPC,.DSTATUS,.FETCH,.PRINT,.EXIT,.DELETE

  START:  MOV     SP,R5   ;СОХРАНИТЬ ТЕКУЩИЙ УКАЗАТЕЛЬ СТЕКА
          .CSISPC #OUTSP,#DEFEXT ;ВВОД КОМАНДНОЙ СТРОКИ
          MOV     R5,SP   ;ВОССТАНОВИТЬ УКАЗАТЕЛЬ СТЕКА
          .DSTAT  #STAT,#OUTSP   ;ПРОВЕРИТЬ НАЛИЧИЕ ДРАЙВЕРА
                                 ;ВЫХОДНОГО УСТРОЙСТВА
          TST     STAT+4         ;ДРАЙВЕР ЗАГРУЖЕН?
          BNE     2¤             ;ДА
          .FETCH  #DEVLOD,#INSPEC;НЕТ-ЗАГРУЗИТЬ ДРАЙВЕР
          BCC     2¤
          .PRINT  #FEFAIL
          .EXIT
  2¤:     .DELETE #AREA,#0,#INSPEC;УДАЛИТЬ ФАЙЛ
          BCC     3¤
          .PRINT  #NOFILE
          BR      START
  3¤:     .PRINT  #FILDEL
          .EXIT

  AREA:   .BLKW   2
  STAT:   .BLKW   4
  DEFEXT: .WORD   0,0,0,0
  FEFAIL: .ASCIZ  /ОШИБКА .FETCH/
  NOFILE: .ASCIZ  /ФАЙЛ НЕ НАЙДЕН/
  FILDEL: .ASCIZ  /ФАЙЛ УДАЛЕН/
          .EVEN
  OUTSP:  .BLKW   5*3     ;СПЕЦИФИКАЦИИ ВЫХ.ФАЙЛОВ
  INSPEC: .BLKW   4*6     ;СПЕЦИФИКАЦИИ ВХ.ФАЙЛОВ
  DEVLOD: .BLKW   1       ;АДРЕС ЗАГРУЗКИ ДРАЙВЕРА
          .END    START

5.3.6.1. Передача информации о переключателях программе пользователя.

В общем и специальном режимах работы CSI переключатели и их аргументы пересылаются в стек. Переключатель представляет собой наклонную черту (/), за которой следует имя переключателя (символ КОИ-7). За переключателем может следовать аргумент, перед которым ставится разделитель (:). Аргумент может быть восьмеричным или десятичным числом (числом с точкой), или комбинацией буквенно-цифровых символов (от одного до трёх), первый из которых - буква. В командной строке переключатели могут быть связаны с файлами.

Например: *DK:FOO/A,DX1:FILE.OBJ/A:100

В этом случае имеется два переключателя а, первый из которых связан с входным файлом FOO, второй связан с входным файлом FILE:OBJ и имеет аргумент 100₍₈₎.

В табл. 10 приводится формат содержимого стека после выполнения запроса .CSIGEN или .CSISPC. Указатель стека будет содержать адрес первого слова.

Например, после обработки CSI командной строки

     *FILE/B:20.,FIL2/E=DX1:INPUT/X:SY:20

Стек будет содержать значения, описанные в табл. 11.

Примечание.

Во многих случаях, программе пользователя не требуется обработка переключателей посредством CSI. Однако, возможен непреднамеренный ввод переключателей пользователем. В этом случае, рекомендуется сохранить значение указателя стека перед вызовом CSI, а затем восстановить его. Заметим, что командная строка без переключателей перемещает указатель стека на одно слово.

5.3.7. .ABTIO

Запрос .ABTIO позволяет текущему заданию запретить все операции ввода - вывода на указанном канале, не прерывая выполнения программы.

Запрещается использовать .ABTIO в подпрограммах завершения.

Формат макрокоманды:

.ABTIO CHAN

5.3.8. .CSTAT (режим FB, XM)

Запрос .CSTAT передаёт программе пользователя информацию о состоянии канала.

Формат макрокоманды:

.CSTAT AREA,CHAN,ADDR

Формат блока аргументов:

       AREA:   .BYTE   CHAN,27
               .WORD   ADDR

Пример.

          .TITLE  CSTAT.MAC
  ;В ЭТОМ ПРИМЕРЕ ЗАПРОС .CSTAT ИСПОЛЬЗУЕТСЯ ДЛЯ ОПРЕДЕЛЕНИЯ
  ;УСТРОЙСТВА, СВЯЗАНОГО С УКАЗАННЫМ КАНАЛОМ.

          .MCALL  .CSTAT,.CSIGEN,.PRINT,.EXIT

  START:  MOV     SP,R5
          .CSIGEN #DEVSDC,#DEFEXT ;ВВОД КОМАНДНОЙ СТРОКИ
          MOV     R5,SP
          .CSTAT  #AREA,#0,#ADDR  ;ПОЛУЧИТЬ ИНФОРМАЦИЮ О
                                  ;КАНАЛЕ
          BCS     NOCHAN          ;КАНАЛ НЕ ОТКРЫТ
          MOV     #ADDR+10,R5
          MOV     (R5)+,R0
          ADD     (PC)+,R0
          .RAD50  /  0/
          ADD     (R5),R0         ;ПОЛУЧИТЬ ИМЯ УСТРОЙСТВА
          MOV     R0,DEVNAM
          .EXIT

  NOCHAN: .PRINT  #MSG
          .EXIT

  MSG:    .ASCIZ  /НЕТ ВЫХОДНОГО ФАЙЛА - КАНАЛ НЕ ОТКРЫТ/
          .EVEN
  AREA:   .BLKW   5
  ADDR:   .BLKW   6
  DEVNAM: .WORD   0               ;ИМЯ УСТРОЙСТВА
  DEFEXT: .WORD   0,0,0,0

  DEVSDC  =.                      ;АДРЕС ЗАГРУЗКИ ДРАЙВЕРА

          .END    START

5.3.9. .DATE

Запрос .DATE передаёт информацию о текущей дате из системной ячейки даты в регистр R0. Ячейка даты имеет следующий формат:

Разряды 13-10 - месяц;

Разряды 9-5 - день;

Разряды 4-0 - год.

Значение года в разрядах с 0 по 4 является фактическим годом минус 1972.

Формат макрокоманды:

     .DATE

Нулевое значение в R0 указывает на то, что пользователь дату не определил.

Пример.

          .TITLE DATE.MAC
  ;ПРИМЕР ПОДПРОГРАММЫ ОБРАБОТКИ ДАТЫ (ВВЕДЁННОЙ ПО КОМАНДЕ
  ;DATE) С ИСПОЛЬЗОВАНИЕМ ЗАПРОСА .DATE, К КОТОРОЙ МОЖНО
  ;ОБРАТИТЬСЯ ИЗ ПРОГРАММЫ ПОЛЬЗОВАТЕЛЯ.
  ;
  ;ВЫХ.ДАННЫЕ:    R0 = МЕСЯЦ (1-12)
  ;               R1 = ДЕНЬ  (1-31)
  ;               R2 = ГОД   (ДВЕ ПОСЛЕДНИЕ ЦИФРЫ)
  ;
  ;ОШИБКИ:        R0 = 0, ЕСЛИ ДАТА НЕ ВВЕДЕНА
  ;

          .MCALL  .DATE

  DATE::  .DATE           ;ПОЛУЧИТЬ ДАТУ ИЗ R0
          MOV     R0,R2
          BEQ     1¤      ;ВЕТВЛЕНИЕ, ЕСЛИ ДАТА НЕ
                          ;ВВЕДЕНА
          BIC     #37,R2  ;ВЫБРАТЬ ГОД
          ADD     #72,R2
          MOV     R0,R1
          ASL     R1      ;ВЫБРАТЬ ДЕНЬ
          ASL     R1
          ASL     R1
          SWAB    R1
          BIC     #37,R1  ;ВЫБРАТЬ МЕСЯЦ
          SWAB    R0
          ASR     R0
          ASR     R0
          BIC     #37,R0
  1¤:     RETURN          ;ВЫХОД ИЗ ПОДПРОГРАММЫ
          .END

5.3.10. .DEVICE (режим FB, XM)

Запрос .DEVICE позволяет записать определённые значения по указанным адресам после выхода из программы (по .EXIT или СУ/C). Эта функция в основном используется для записи в регистры устройств необходимых значений.

В программе может быть несколько запросов .DEVICE и пользователь может связать все таблицы адресов в одну таблицу.

Запрос .DEVICE игнорируется, если он выдаётся из виртуального задания в режиме XM.

Формат макрокоманды:

.DEVICE AREA,ADDR[,LINK]

Таблица адресов и значений может иметь два формата - связанный и не связанный. Оба формата должны оканчиваться нулём. Связанный формат должен иметь в первом слове также ноль. На рис. 5 показаны различные форматы таблицы адресов и значений.

Рис.5

5.3.11. .DSTATUS

Запрос .DSTATUS используется для получения  информации об определённом устройстве.

Формат макрокоманды:

.DSTATUS DSTBLK,DEVNAM

Второе слово представляет собой длину драйвера устройства в байтах.

Третье слово представляет собой адрес загрузки драйвера плюс 6. Если 0 - драйвера в памяти нет.

Четвёртое слово представляет собой ёмкость устройства (в блоках) для устройств с произвольным доступом к данным или 0 для устройств с последовательным доступом к данным.

Имя устройства в DEVNAM может быть логическим именем, присвоенным пользователем.

Пример использования .DSTATUS см. в описании запроса .CSISPC.

5.3.12. .EXIT

Запрос .EXIT вызывает окончание выполнения программы пользователя и передаёт управление KMON.

Перед выходом из программы выполнение всех инициированных операций ввода-вывода и /или подпрограмм завершения будет закончено. Все невыполненные запросы .MRKT и .CMKT будут аннулированы.

Если часть фоновой программы занимает область памяти KMON и USR, то она будет записана в блоки для временного хранения данных на системное устройство (если ранее была выполнена команда SET EXIT SWAP). После этого KMON и USR загружаются в память и управление передаётся клавиатурному монитору. Если была выполнена команда SET EXIT NOSWAP, то программа пользователя просто перезаписывается.

Если R0 = 0 во время выполнения .EXIT, то выполняется операция аналогичная .HRESET, запрещающая последующее выполнение команд REENTER, START или CLOSE.

Запрос .EXIT позволяет программе передать команды клавиатурному монитору, используя ячейки 500-777, для их последующего выполнения. Для этого необходимо:

1. ячейка 510 должна содержать общее количество байтов в команде, которая будет передана KMON;
2. команды записываются, начиная с ячейки 512; строка должна быть записана в символах КОИ-7 и не должна содержать <ВК> или <ПС>; например:

         .=510
         .WORD B-A
     A:  .ASCIZ /COPY A.MAC W.MAC/
         .ASCIZ /DELETE A.MAC/
     B=  .

3. программа пользователя должна установить 5 или 11 разряд в ССЗ перед выполнением .EXIT; содержимое R0 должно быть нулевым.

Когда запрос .EXIT используется для передачи команд необходимо учитывать следующее:

1. если это свойство используется программой, которая вызывается с помощью косвенного файла, то все команды, следующие в косвенном файле за командой, инициирующей пуск этой программы, выполняться не будут;
2. косвенный файл может быть вызван, используя это свойство, только в том случае если передаваемая KMON строка содержит единственную спецификацию файла; попытка передачи нескольких косвенных файлов или комбинаций косвенных файлов с другими командами KMON приводит к неправильным результатам;
3. .EXIT в подпрограмме завершения недопустим. Заметим, что запрос .EXIT изменяет текущее положение указателя стека.

Формат макрокоманды:

.EXIT

Пример.

          .TITLE  EXIT.MAC
  ;В ЭТОМ ПРИМЕРЕ, ПОСЛЕ ЗАВЕРШЕНИЯ ПРОГРАММЫ,
  ;КЛАВИАТУРНОМУ МОНИТОРУ ПЕРЕДЕТСЯ КОМАНДНАЯ
  ;СТРОКА НА ПЕЧАТЬ СПРАВОЧНИКА УСТРОЙСТВА DK:
          .MCALL  .EXIT
  CHNIF¤  = 4000
  JSW     = 44

  START:  MOV     #510,R0
          MOV     #CMDSTR,R1
          MOV     #START,SP

  1¤:     MOVB    (R1)+,(R0)+
          CMP     R1,#CMDEND
          BLO     1¤
          BIS     #CHNIF¤,@#JSW ;УСТАНОВИТЬ 11-ЫЙ РАЗРЯД
                                ;В JSW
          CLR     R0            ;В R0 ДОЛЖЕН БЫТЬ 0
          .EXIT

  CMDSTR: .WORD   CMDEND-CMDSTR ;ДЛИНА КОМАНДНОЙ СТРОКИ
          .ASCIZ  "DIRECT/FULL *.MAC" ;КОМАНДНАЯ СТРОКА
  CMDEND:
          .EVEN
          .END    START

5.3.13. .FETCH, .RELEAS

Запрос .FETCH загружает драйвер устройства из системного устройства в оперативную память.

Формат макрокоманды:

.FETCH ADDR,DEVNAM

После выполнения .FETCH, R0 содержит адрес первой, расположенной выше драйвера, ячейки оперативной памяти. Если драйвер уже загружен в память, R0 будет содержать адрес загрузки ADDR.

Для выполнения запросов

необходимо наличие в памяти драйверов соответствующих устройств.

В режиме FB, драйверы для основной программы или системного задания должны загружаться по команде LOAD перед их выполнением.

В режиме XM, драйверы устройств должны загружаться в любую область памяти (фоновую или основную) по команде LOAD перед загрузкой программ.

Пример использования .FETCH см. в описании запроса .CSISPC.

Запрос .RELEAS удаляет драйвер указанного устройства из памяти. Запрос .RELEAS игнорируется, если драйвер:

1. является частью RMON (т.е. является драйвером системного устройства);
2. отсутствует в памяти;
3. был загружен по команде LOAD.

Запрос .RELEAS в основной программе или в системном задании под управлением монитора FB(XM) всегда игнорируется, т.к. мониторы FB или XM могут использовать только те драйверы, которые были загружены по команде LOAD.

Формат макрокоманды:

.RELEAS DEVNAM

Пример.

          .TITLE  RELEAS.MAC
  ;В ЭТОМ ПРИМЕРЕ ДРАЙВЕР PC: ЗАГРУЖАЕТСЯ В ПАМЯТЬ,
  ;А ЗАТЕМ ПО ЗАПРОСУ .RELEAS УДАЛЯЕТСЯ ИЗ ПАМЯТИ.

          .MCALL  .FETCH,.RELEAS,.EXIT,.PRINT

  START:  .FETCH  #DSPACE,#DEVNAM ;ЗАГРУЗИТЬ ДРАЙВЕР
          BCS     FERR
          .RELEAS #DEVNAM         ;УДАЛИТЬ ДРАЙВЕР
          BR      START

  FERR:   .PRINT  #NODEV
          .EXIT
  DEVNAM: .RAD50  /PC /
  NODEV:  .ASCIZ  " УСТРОЙСТВО ОТСУТСТВУЕТ !"
          .EVEN
  DSPACE:

          .END    START

5.3.14. .FORK

Запрос .FORK используется в драйверах для синхронизации работы системы. Запросу .FORK должен предшествовать запрос .INTEN, .FORK требует для своего выполнения блок памяти из 4-х слов. Содержимое регистров R4 и R5 после выполнения запроса сохраняется. .FORK используется в том случае, когда должен быть упорядочен доступ к системным ресурсам или должна быть выполнена не критическая по времени, но большая по размеру, часть программы. После обработки монитором запроса .FORK прерывание от устройства будет запрещено, и драйвер будет работать на нулевом приоритете.

Формат макрокоманды:

.FORK FKBLK

5.3.15. .FPROT

С помощью запроса .FPROT устанавливается или отменяется защита файла (от удаления).

На защищённый файл не распространяется действия запросов .CLOSE, .DELETE, .ENTER и .RENAME. Однако данные, хранящиеся в защищённом файле, можно модифицировать. Например, использование запроса .LOOKUP для защищённого файла за которым следует .WRITE, использующий тот же канал, допускается.

Защита файла от удаления реализуется установкой 15-го разряда в слове состояния справочника устройства для указанного файла.

Формат макрокоманды:

.FPROT AREA,CHAN,DBLK,PROT

Формат блока аргументов:

       AREA:   .BYTE   CHAN,43
               .WORD   DBLK
               .WORD   PROT

Пример.

          .TITLE FPROT.MAC
  ;В ПРИМЕРЕ ИСПОЛЬЗУЮТСЯ ЗАПРОСЫ .FPROT И .SFDAT
  ;ДЛЯ УСТАНОВКИ ЗАЩИТЫ УКАЗАННОГО ФАЙЛА И
  ;ИЗМЕНЕНИЯ ДАТЫ СОЗДАНИЯ ФАЙЛА НА ТЕКУЩУЮ ДАТУ.
  ;КОМАНДНАЯ СТРОКА ВВОДИТСЯ С ТЕРМИНАЛА.

          .MCALL .FPROT,.FETCH,.CSISPC,.DSTATUS,.SFDAT
          .MCALL .PRINT,.EXIT

  START:  .CSISPC #OUTSP,#DEFEXT  ;ВВОД КОМАНДНОЙ СТРОКИ
          .DSTAT  #STAT,#INSPEC   ;ПРОВЕРИТЬ НАЛИЧИЕ
                                  ;УСТРОЙСТВА
          TST     STAT+4          ;ДРАЙВЕР ЗАГРУЖЕН?
          BNE     1¤              ;ДА
          .FETCH  #DRVLOD,#INSPEC ;НЕТ-ЗАГРУЗИТЬ ДРАЙВЕР
          BCC     1¤
          .PRINT  #LOFAIL
          BR      START
  1¤:     .FPROT  #EMTBLK,#0,#INSPEC,#1;УСТАНОВИТЬ ЗАЩИТУ
                                       ;ФАЙЛА
          BCC     2¤
          .PRINT  #PRFAIL
          BR      START
  2¤:     .SFDAT  #EMTBLK,#0,#INSPEC,#0;ИЗМЕНИТЬ ДАТУ НА
                                       ;ТЕКУЩУЮ
          BCC     3¤
          .PRINT  #SDFAIL
          BR      START
  3¤:     .EXIT

  EMTBLK: .BLKW   4
  DEFEXT: .WORD   0,0,0,0
  STAT:   .BLKW   4              ;БЛОК СОСТОЯНИЯ УСТРОЙСТВА
  LOFAIL: .ASCIZ  /ОШИБКА ЗАПРОСА .FETCH/
  PRFAIL: .ASCIZ  /ОШИБКА ЗАПРОСА .FPROT/
  SDFAIL: .ASCIZ  /ОШИБКА ЗАПРОСА .SFDAT/
          .EVEN
  OUTSP:  .BLKW   5*3
  INSPEC: .BLKW   4*6
  DRVLOD: .BLKW   1
          .END    START

5.3.16. .GTIM

Запрос .GTIM позволяет программе определить текущее время суток. Величина времени определяется в тиках (1 тик = 1/50 с).

Формат макрокоманды:

.GTIM AREA,ADDR

Формат блока аргументов:

       AREA:   .BYTE   0,21
               .WORD   ADDR

Пользователь должен предусмотреть в своей программе операцию преобразования тиков в часы-минуты-секунды. В режиме FB величина времени автоматически восстанавливается после 24:00:, в режиме SJ операция восстановления выполняется, если при генерации системы была определена поддержка таймера.

Пример.

          .TITLE  GTIM.MAC

  ;В ЭТОМ ПРИМЕРЕ ПОЛЬЗОВАТЕЛЬ ПОЛУЧАЕТ ТЕКУЩЕЕ ВРЕМЯ
  ;В ТИКАХ.

          .MCALL  .GTIM,.EXIT

  START:  .GTIM   #AREA,#TICKS    ;ОПРЕДЕЛИТЬ ТЕКУЩЕЕ
                                  ;ВРЕМЯ
          .EXIT

  TICKS:  .WORD   0,0
  AREA:   .BLKW   2

          .END START

5.3.17. .GTJB

Запрос .GTJB позволяет программе определить номер выполняемого задания, нижнюю границу памяти и другие параметры задания.

Формат макрокоманды:

.GTJB AREA,ADDR[,JOBBLK]

Формат блока аргументов:

       AREA:   .BYTE   0,20
               .WORD   ADDR
               .WORD   JOBBLK

Примечание. Информацию необходимую для управления выполнением основного задания, монитор хранит в, так называемой, смешанной области, которая создаётся во время загрузки основной программы в младших адресах основной области памяти.

Слово 4 содержит адрес, с которого начинается область каналов ввода-вывода. Обычно этот адрес находится в пределах RMON. Однако, после выполнения .CDFN, область каналов ввода-вывода заменяется на область, адрес которой указывается пользователем.

Пример.

          .TITLE  GTJB.MAC
  ;В ДАННОМ ПРИМЕРЕ С ПОМОЩЬЮ ЗАПРОСА .GTJB ОПРЕДЕЛЯЕТСЯ
  ;ЗАГРУЖЕНО ЛИ ОСНОВНОЕ ЗАДАНИЕ.
  ;ПРОГРАММА МОЖЕТ ВЫПОЛНЯТЬСЯ КАК ПОД УПРАВЛЕНИЕМ МОНИТОРА
  ;FB, ИМЕЮЩЕГО ПОДДЕРЖКУ СИСТЕМНЫХ ЗАДАНИЙ, ТАК И ПОД
  ;УПРАВЛЕНИЕМ МОНИТОРА FB, КОТОРЫЙ НЕ ИМЕЕТ ПОДДЕРЖКИ
  ;СИСТЕМНЫХ ЗАДАНИЙ.

          .MCALL  .GVAL,.GTJB,.PRINT,.EXIT

          SYSGEN = 372            ;СЛОВО ПАРАМЕТРОВ ГЕНЕРАЦИИ
          SYSJOB = 40000          ;РАЗРЯД СИСТЕМНОГО ЗАДАНИЯ

  START:  MOV     #2,     R1
          .GVAL   #LIST,  #SYSGEN ;ПОЛУЧИТЬ В R0 СОДЕРЖИМОЕ
                                  ;ЯЧЕЙКИ МОНИТОРА
          BIT     #SYSJOB,R0      ;ЕСТЬ ПОДДЕРЖКА СИСТЕМНОГО
                                  ;ЗАДАНИЯ
          BEQ     1¤
          MOV     #16,    R1      ;НОМЕР ОСНОВНОГО ЗАДАНИЯ=16

  1¤:     .GTJB   #LIST,#JOBARG,R1;ПОЛУЧИТЬ ПАРАМЕТРЫ
          BCS     2¤
          .PRINT  #FGLOAD
          .EXIT
  2¤:     .PRINT  #NOFG
          .EXIT

  LIST:   .BLKW   3
  JOBARG: .BLKW   12.             ;БЛОК ПАРАМЕТРОВ ЗАДАНИЯ
  FGLOAD: .ASCIZ  / ПРОГРАММА В ОСНОВНОЙ ОБЛАСТИ ПАМЯТИ/
  NOFG:   .ASCIZ  /НЕТ ПРОГРАММЫ В ОСНОВНОЙ ОБЛАСТИ/
          .EVEN
          .END    START